configure.in

   1 dnl
   2 dnl  $Id$
   3 dnl
   4 dnl  Copyright © 2003 Keith Packard
   5 dnl
   6 dnl  Permission to use, copy, modify, distribute, and sell this software and its
   7 dnl  documentation for any purpose is hereby granted without fee, provided that
   8 dnl  the above copyright notice appear in all copies and that both that
   9 dnl  copyright notice and this permission notice appear in supporting
  10 dnl  documentation, and that the name of Keith Packard not be used in
  11 dnl  advertising or publicity pertaining to distribution of the software without
  12 dnl  specific, written prior permission.  Keith Packard makes no
  13 dnl  representations about the suitability of this software for any purpose.  It
  14 dnl  is provided "as is" without express or implied warranty.
  15 dnl
  16 dnl  KEITH PACKARD DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
  17 dnl  INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
  18 dnl  EVENT SHALL KEITH PACKARD BE LIABLE FOR ANY SPECIAL, INDIRECT OR
  19 dnl  CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
  20 dnl  DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
  21 dnl  TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
  22 dnl  PERFORMANCE OF THIS SOFTWARE.
  23 dnl
  24 dnl Process this file with autoconf to create configure.
  25
  26 AC_INIT(fonts.dtd)
  27
  28 dnl ==========================================================================
  29 dnl                               Versioning
  30 dnl ==========================================================================
  31
  32 dnl This is the package version number, not the shared library
  33 dnl version.  This same version number must appear in fontconfig/fontconfig.h
  34 dnl Yes, it is a pain to synchronize version numbers.  Unfortunately, it's
  35 dnl not possible to extract the version number here from fontconfig.h
  36 AM_INIT_AUTOMAKE(fontconfig, 2.4.1)
  37 AM_MAINTAINER_MODE
  38
  39 dnl libtool versioning
  40
  41 dnl bump revision when fixing bugs
  42 dnl bump current and age, reset revision to zero when adding APIs
  43 dnl bump current, leave age, reset revision to zero when changing/removing APIS
  44 LT_CURRENT=2
  45 LT_REVISION=0
  46 AC_SUBST(LT_CURRENT)
  47 AC_SUBST(LT_REVISION)
  48 LT_AGE=1
  49
  50 LT_VERSION_INFO="$LT_CURRENT:$LT_REVISION:$LT_AGE"
  51 AC_SUBST(LT_VERSION_INFO)
  52
  53 LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
  54 AC_SUBST(LT_CURRENT_MINUS_AGE)
  55
  56 dnl ==========================================================================
  57
  58 AM_CONFIG_HEADER(config.h)
  59
  60 AC_PROG_CC
  61 AC_PROG_INSTALL
  62 AC_PROG_LN_S
  63 AC_LIBTOOL_WIN32_DLL
  64 AM_PROG_LIBTOOL
  65 AC_PROG_MAKE_SET
  66
  67 dnl ==========================================================================
  68
  69 case "$host" in
  70   *-*-mingw*)
  71     os_win32=yes
  72     ;;
  73   *)
  74     os_win32=no
  75 esac
  76 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
  77
  78 if test "$os_win32" = "yes"; then
  79   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
  80 fi
  81 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
  82
  83 WARN_CFLAGS=""
  84 if test "x$GCC" = "xyes"; then
  85         WARN_CFLAGS="-Wall -Wpointer-arith -Wstrict-prototypes \
  86         -Wmissing-prototypes -Wmissing-declarations \
  87         -Wnested-externs -fno-strict-aliasing"
  88         AC_DEFINE_UNQUOTED(HAVE_WARNING_CPP_DIRECTIVE,1,
  89         [Can use #warning in C files])
  90 fi
  91 AC_SUBST(WARN_CFLAGS)
  92
  93
  94 dnl ==========================================================================
  95
  96 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
  97
  98 dnl ==========================================================================
  99
 100 # Setup for compiling build tools (fc-glyphname, etc)
 101 AC_MSG_CHECKING([for a C compiler for build tools])
 102 if test $cross_compiling = yes; then
 103   AC_CHECK_PROGS(CC_FOR_BUILD, gcc cc)
 104 else
 105   CC_FOR_BUILD=$CC
 106 fi
 107 AC_MSG_RESULT([$CC_FOR_BUILD])
 108 AC_SUBST(CC_FOR_BUILD)
 109
 110 AC_MSG_CHECKING([for suffix of executable build tools])
 111 if test $cross_compiling = yes; then
 112   cat >conftest.c <<\_______EOF
 113 int
 114 main ()
 115 {
 116   exit (0);
 117 }
 118 _______EOF
 119   for i in .exe ""; do
 120     compile="$CC_FOR_BUILD conftest.c -o conftest$i"
 121     if AC_TRY_EVAL(compile); then
 122       if (./conftest) 2>&AC_FD_CC; then
 123         EXEEXT_FOR_BUILD=$i
 124         break
 125       fi
 126     fi
 127   done
 128   rm -f conftest*
 129   if test "${EXEEXT_FOR_BUILD+set}" != set; then
 130     AC_MSG_ERROR([Cannot determine suffix of executable build tools])
 131   fi
 132 else
 133   EXEEXT_FOR_BUILD=$EXEEXT
 134 fi
 135 AC_MSG_RESULT([$EXEEXT_FOR_BUILD])
 136 AC_SUBST(EXEEXT_FOR_BUILD)
 137
 138 dnl ==========================================================================
 139
 140 AC_ARG_WITH(arch,      [  --with-arch=ARCH      Force architecture to ARCH], arch="$withval", arch=auto)
 141
 142 if test $cross_compiling = yes; then
 143         case "$arch" in
 144         auto)
 145                 AC_MSG_ERROR([Cannot autodetect architecture in cross compile environment]
 146                              [Use --with-arch=ARCH to specify architecture])
 147                 ;;
 148         esac
 149 fi
 150
 151 ARCHITECTURE=$arch
 152 AC_SUBST(ARCHITECTURE)
 153
 154 dnl ==========================================================================
 155
 156 # Checks for header files.
 157 AC_HEADER_DIRENT
 158 AC_HEADER_STDC
 159 AC_CHECK_HEADERS([fcntl.h stdlib.h string.h unistd.h])
 160
 161 # Checks for typedefs, structures, and compiler characteristics.
 162 AC_C_CONST
 163 AC_C_INLINE
 164 AC_TYPE_PID_T
 165
 166 # Checks for library functions.
 167 AC_FUNC_VPRINTF
 168 AC_FUNC_MMAP
 169 AC_CHECK_FUNCS([geteuid getuid link memmove memset mkstemp strchr strrchr strtol getopt getopt_long sysconf ftruncate chsize rand_r])
 170
 171 #
 172 # Checks for iconv
 173 #
 174 AC_MSG_CHECKING([for a usable iconv])
 175 ICONV_LIBS=""
 176 AC_TRY_LINK([#include <iconv.h>],
 177             [iconv_open ("from", "to");],
 178             [use_iconv=1],
 179             [use_iconv=0])
 180 if test x$use_iconv = x1; then
 181         AC_MSG_RESULT([libc])
 182 else
 183         # try using libiconv
 184         fontconfig_save_libs="$LIBS"
 185         LIBS="$LIBS -liconv"
 186
 187         AC_TRY_LINK([#include <iconv.h>],
 188                     [iconv_open ("from", "to");],
 189                     [use_iconv=true],
 190                     [use_iconv=false])
 191
 192         if test x$use_iconv = x1; then
 193                 ICONV_LIBS="-liconv"
 194                 AC_MSG_RESULT([libiconv])
 195         else
 196                 AC_MSG_RESULT([no])
 197         fi
 198
 199         LIBS="$fontconfig_save_libs"
 200 fi
 201 AC_SUBST(ICONV_LIBS)
 202 AC_DEFINE_UNQUOTED(USE_ICONV,$use_iconv,[Use iconv.])
 203
 204 #
 205 # Checks for FreeType
 206 #
 207
 208 AC_ARG_WITH(freetype-config, [  --with-freetype-config=PROG   Use FreeType configuration program PROG], freetype_config=$withval, freetype_config=yes)
 209
 210 if test "$freetype_config" = "yes"; then
 211         AC_PATH_PROG(ft_config,freetype-config,no)
 212         if test "$ft_config" = "no"; then
 213                 AC_MSG_ERROR([You must have freetype installed; see http://www.freetype.org/])
 214         fi
 215 else
 216         ft_config="$freetype_config"
 217 fi
 218
 219 FREETYPE_CFLAGS="`$ft_config --cflags`"
 220 FREETYPE_LIBS="`$ft_config --libs`"
 221
 222 AC_SUBST(FREETYPE_LIBS)
 223 AC_SUBST(FREETYPE_CFLAGS)
 224
 225 #
 226 # Check to see whether we have:
 227 #  FT_Get_Next_Char
 228 #  FT_Get_BDF_Property
 229 #  FT_Get_PS_Font_Info
 230 #  FT_Has_PS_Glyph_Names
 231 #
 232
 233 fontconfig_save_libs="$LIBS"
 234 fontconfig_save_cflags="$CFLAGS"
 235 LIBS="$LIBS $FREETYPE_LIBS"
 236 CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
 237 AC_CHECK_FUNCS(FT_Get_Next_Char FT_Get_BDF_Property FT_Get_PS_Font_Info FT_Has_PS_Glyph_Names FT_Get_X11_Font_Format)
 238 AC_CHECK_MEMBER(FT_Bitmap_Size.y_ppem,
 239                 HAVE_FT_BITMAP_SIZE_Y_PPEM=1,
 240                 HAVE_FT_BITMAP_SIZE_Y_PPEM=0,
 241 [#include <ft2build.h>
 242 #include FT_FREETYPE_H])
 243 AC_DEFINE_UNQUOTED(HAVE_FT_BITMAP_SIZE_Y_PPEM,$HAVE_FT_BITMAP_SIZE_Y_PPEM,
 244                    [FT_Bitmap_Size structure includes y_ppem field])
 245 CFLAGS="$fontconfig_save_cflags"
 246 LIBS="$fontconfig_save_libs"
 247
 248 #
 249 # Check expat configuration
 250 #
 251
 252 AC_ARG_WITH(expat,             [  --with-expat=DIR              Use Expat in DIR], expat=$withval, expat=yes)
 253 AC_ARG_WITH(expat-includes,    [  --with-expat-includes=DIR     Use Expat includes in DIR], expat_includes=$withval, expat_includes=yes)
 254 AC_ARG_WITH(expat-lib,         [  --with-expat-lib=DIR          Use Expat library in DIR], expat_lib=$withval, expat_lib=yes)
 255
 256 if test "$enable_libxml2" != "yes"; then
 257         case "$expat" in
 258         no)
 259         ;;
 260         *)
 261                 case "$expat_includes" in
 262                 yes)
 263                         case "$expat" in
 264                         yes)
 265                                 ;;
 266                         *)
 267                                 EXPAT_CFLAGS="-I$expat/include"
 268                                 ;;
 269                         esac
 270                         ;;
 271                 no)
 272                         EXPAT_CFLAGS=""
 273                         ;;
 274                 *)
 275                         EXPAT_CFLAGS="-I$expat_includes"
 276                         ;;
 277                 esac
 278                 case "$expat_lib" in
 279                 yes)
 280                         case "$expat" in
 281                         yes)
 282                                 EXPAT_LIBS="-lexpat"
 283                                 ;;
 284                         *)
 285                                 EXPAT_LIBS="-L$expat/lib -lexpat"
 286                                 ;;
 287                         esac
 288                         ;;
 289                 no)
 290                         ;;
 291                 *)
 292                         EXPAT_LIBS="-L$expat_lib -lexpat"
 293                         ;;
 294                 esac
 295
 296                 expatsaved_CPPFLAGS="$CPPFLAGS"
 297                 CPPFLAGS="$CPPFLAGS $EXPAT_CFLAGS"
 298                 expatsaved_LIBS="$LIBS"
 299                 LIBS="$LIBS $EXPAT_LIBS"
 300
 301                 AC_CHECK_HEADER(expat.h)
 302                 case "$ac_cv_header_expat_h" in
 303                 no)
 304                         AC_CHECK_HEADER(xmlparse.h)
 305                         case "$ac_cv_header_xmlparse_h" in
 306                         no)
 307                                 have_expat_header=no;
 308                                 ;;
 309                         yes)
 310                                 HAVE_XMLPARSE_H=1
 311                                 AC_SUBST(HAVE_XMLPARSE_H)
 312                                 AC_DEFINE_UNQUOTED(HAVE_XMLPARSE_H,$HAVE_XMLPARSE_H,
 313                                 [Use xmlparse.h instead of expat.h])
 314                                 have_expat_header=yes
 315                                 ;;
 316                         esac
 317                         ;;
 318                 yes)
 319                         have_expat_header=yes
 320                         ;;
 321                 esac
 322                 case "$have_expat_header" in
 323                 no)
 324                         expat=no
 325                         ;;
 326                 yes)
 327                         AC_CHECK_FUNCS(XML_SetDoctypeDeclHandler)
 328                         case "$ac_cv_func_XML_SetDoctypeDeclHandler" in
 329                         yes)
 330                                 HAVE_EXPAT=1
 331                                 AC_SUBST(HAVE_EXPAT)
 332                                 AC_DEFINE_UNQUOTED(HAVE_EXPAT,$HAVE_EXPAT,
 333                                 [Found a useable expat library])
 334                                 ;;
 335                         *)
 336                                 expat=no
 337                                 ;;
 338                         esac
 339                         ;;
 340                 esac
 341                 CPPFLAGS="$expatsaved_CPPFLAGS"
 342                 LIBS="$expatsaved_LIBS"
 343                 ;;
 344         esac
 345
 346         AC_SUBST(EXPAT_CFLAGS)
 347         AC_SUBST(EXPAT_LIBS)
 348
 349         case "$expat" in
 350         no)
 351                 EXPAT_CFLAGS=""
 352                 EXPAT_LIBS=""
 353
 354                 AC_MSG_WARN([Cannot find usable expat library. Trying to use libxml2 as fallback.])
 355                 ;;
 356         esac
 357 fi
 358
 359 #
 360 # Check libxml2 configuration
 361 #
 362
 363 AC_ARG_ENABLE(libxml2,         [  --enable-libxml2              Use libxml2 instead of Expat])
 364
 365 PKG_PROG_PKG_CONFIG
 366
 367 if test "$enable_libxml2" = "yes" -o "$expat" = "no"; then
 368     PKG_CHECK_MODULES([LIBXML2], [libxml-2.0 >= 2.6])
 369     AC_DEFINE_UNQUOTED(ENABLE_LIBXML2,1,[Use libxml2 instead of Expat])
 370
 371     AC_SUBST(LIBXML2_CFLAGS)
 372     AC_SUBST(LIBXML2_LIBS)
 373 fi
 374
 375 #
 376 # Set default font directory
 377 #
 378
 379 AC_ARG_WITH(default-fonts,     [  --with-default-fonts=DIR      Use fonts from DIR when config is busted], default_fonts="$withval", default_fonts=yes)
 380
 381 case "$default_fonts" in
 382 yes)
 383         if test "$os_win32" = "yes"; then
 384                 FC_DEFAULT_FONTS="WINDOWSFONTDIR"
 385                 AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "WINDOWSFONTDIR",
 386                                    [Windows font directory])
 387         else
 388                 FC_DEFAULT_FONTS="/usr/share/fonts"
 389                 AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "/usr/share/fonts",
 390                                    [System font directory])
 391         fi
 392         ;;
 393 *)
 394         FC_DEFAULT_FONTS="$default_fonts"
 395         AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "$default_fonts",
 396                            [System font directory])
 397         ;;
 398 esac
 399
 400 AC_SUBST(FC_DEFAULT_FONTS)
 401
 402 #
 403 # Add more fonts if available.  By default, add only the directories
 404 # with outline fonts; those with bitmaps can be added as desired in
 405 # local.conf or ~/.fonts.conf
 406 #
 407 AC_ARG_WITH(add-fonts,        [  --with-add-fonts=DIR1,DIR2,...Find additional fonts in DIR1,DIR2,... ], add_fonts="$withval", add_fonts=yes)
 408
 409 case "$add_fonts" in
 410 yes)
 411         FC_ADD_FONTS=""
 412         for dir in /usr/X11R6/lib/X11 /usr/X11/lib/X11 /usr/lib/X11; do
 413                 case x"$FC_ADD_FONTS" in
 414                 x)
 415                         sub="$dir/fonts"
 416                         if test -d "$sub"; then
 417                                 case x$FC_ADD_FONTS in
 418                                 x)
 419                                         FC_ADD_FONTS="$sub"
 420                                         ;;
 421                                 *)
 422                                         FC_ADD_FONTS="$FC_ADD_FONTS,$sub"
 423                                         ;;
 424                                 esac
 425                         fi
 426                         ;;
 427                 esac
 428         done
 429         AC_DEFINE_UNQUOTED(FC_ADD_FONTS,"$add_fonts",[Additional font directories])
 430         ;;
 431 no)
 432         FC_ADD_FONTS=""
 433         ;;
 434 *)
 435         FC_ADD_FONTS="$add_fonts"
 436         AC_DEFINE_UNQUOTED(FC_ADD_FONTS,"$add_fonts",[Additional font directories])
 437         ;;
 438 esac
 439
 440 AC_SUBST(FC_ADD_FONTS)
 441
 442 FC_FONTPATH=""
 443
 444 case "$FC_ADD_FONTS" in
 445 "")
 446         ;;
 447 *)
 448         FC_FONTPATH=`echo $FC_ADD_FONTS |
 449                         sed -e 's/^/<dir>/' -e 's/$/<\/dir>/' -e 's/,/<\/dir> <dir>/g'`
 450         ;;
 451 esac
 452
 453 AC_SUBST(FC_FONTPATH)
 454
 455 #
 456 # Set default cache directory path
 457 #
 458 AC_ARG_WITH(cache-dir,         [ --with-cache-dir=DIR           Use DIR to store cache files (default /var/cache/fontconfig)], fc_cachedir="$withval", fc_cachedir=yes)
 459
 460 case $fc_cachedir in
 461 no|yes)
 462         fc_cachedir=`eval echo "${localstatedir}/cache/"${PACKAGE}`
 463         ;;
 464 *)
 465         ;;
 466 esac
 467 AC_SUBST(fc_cachedir)
 468 FC_CACHEDIR=${fc_cachedir}
 469 AC_SUBST(FC_CACHEDIR)
 470
 471 FC_FONTDATE=`LC_ALL=C date`
 472
 473 AC_SUBST(FC_FONTDATE)
 474
 475 AC_ARG_WITH(confdir,           [  --with-confdir=DIR            Use DIR to store configuration files (default /etc/fonts)], confdir="$withval", confdir=yes)
 476
 477 #
 478 # Set CONFDIR and FONTCONFIG_PATH
 479 #
 480
 481 case "$confdir" in
 482 no|yes)
 483         confdir='${sysconfdir}'/fonts
 484         ;;
 485 *)
 486         ;;
 487 esac
 488 AC_SUBST(confdir)
 489 CONFDIR=${confdir}
 490 AC_DEFINE_UNQUOTED(CONFDIR, "$CONFDIR",[Font configuration directory])
 491 AC_SUBST(CONFDIR)
 492
 493 #
 494 # Find out what language orthographies are included
 495 #
 496
 497 ORTH_FILES=`cd ${srcdir}/fc-lang && echo *.orth`
 498 AC_SUBST(ORTH_FILES)
 499
 500 #
 501 # Let people not build/install docs if they don't have docbook
 502 #
 503
 504 AC_CHECK_PROG(HASDOCBOOK, docbook2html, yes, no)
 505
 506 AM_CONDITIONAL(USEDOCBOOK, test "x$HASDOCBOOK" = xyes)
 507
 508 default_docs="yes"
 509 #
 510 # Check if docs exist or can be created
 511 #
 512 if test x$HASDOCBOOK = xno; then
 513         if test -f doc/fonts-conf.5; then
 514                 :
 515         else
 516                 default_docs="no"
 517         fi
 518 fi
 519
 520 AC_ARG_ENABLE(docs,           [  --disable-docs                Don't build and install documentation],,enable_docs=$default_docs)
 521
 522 AM_CONDITIONAL(ENABLE_DOCS, test "x$enable_docs" = xyes)
 523
 524 if test "x$enable_docs" = xyes; then
 525         DOCSRC="doc"
 526         tmp=funcs.$$
 527         cat $srcdir/doc/*.fncs | awk '
 528         /^@TITLE@/      { if (!done) { printf ("%s\n", $2); done = 1; } }
 529         /^@FUNC@/       { if (!done) { printf ("%s\n", $2); done = 1; } }
 530         /^@@/           { done = 0; }' > $tmp
 531         DOCMAN3=`cat $tmp | awk '{ printf ("%s.3 ", $1); }'`
 532         echo DOCMAN3 $DOCMAN3
 533         rm -f $tmp
 534 else
 535         DOCSRC=""
 536         DOCMAN3=""
 537 fi
 538
 539 AC_SUBST(DOCSRC)
 540 AC_SUBST(DOCMAN3)
 541
 542 #
 543 # Figure out where to install documentation
 544 #
 545
 546 AC_ARG_WITH(docdir,           [  --with-docdir=DIR             Use DIR to store documentation files (default ${datadir}/doc/fontconfig)], confdir="$withval")
 547
 548 if test "x$with_docdir" = "x" ; then
 549   DOCDIR='${datadir}/doc/fontconfig'
 550 else
 551   DOCDIR=$with_docdir
 552 fi
 553
 554 AC_SUBST(DOCDIR)
 555
 556
 557 AC_OUTPUT([
 558 Makefile
 559 fontconfig/Makefile
 560 fc-lang/Makefile
 561 fc-glyphname/Makefile
 562 fc-case/Makefile
 563 fc-arch/Makefile
 564 src/Makefile
 565 src/fontconfig.def
 566 conf.d/Makefile
 567 fc-cache/Makefile
 568 fc-cat/Makefile
 569 fc-list/Makefile
 570 fc-match/Makefile
 571 doc/Makefile
 572 doc/version.sgml
 573 test/Makefile
 574 fontconfig.spec
 575 fontconfig.pc
 576 fonts.conf
 577 fontconfig-zip
 578 ])