configure.in

   1 dnl
   2 dnl  $Id$
   3 dnl
   4 dnl  Copyright © 2003 Keith Packard
   5 dnl
   6 dnl  Permission to use, copy, modify, distribute, and sell this software and its
   7 dnl  documentation for any purpose is hereby granted without fee, provided that
   8 dnl  the above copyright notice appear in all copies and that both that
   9 dnl  copyright notice and this permission notice appear in supporting
  10 dnl  documentation, and that the name of Keith Packard not be used in
  11 dnl  advertising or publicity pertaining to distribution of the software without
  12 dnl  specific, written prior permission.  Keith Packard makes no
  13 dnl  representations about the suitability of this software for any purpose.  It
  14 dnl  is provided "as is" without express or implied warranty.
  15 dnl
  16 dnl  KEITH PACKARD DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
  17 dnl  INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
  18 dnl  EVENT SHALL KEITH PACKARD BE LIABLE FOR ANY SPECIAL, INDIRECT OR
  19 dnl  CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
  20 dnl  DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
  21 dnl  TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
  22 dnl  PERFORMANCE OF THIS SOFTWARE.
  23 dnl
  24 dnl Process this file with autoconf to create configure.
  25
  26 AC_INIT(fonts.dtd)
  27
  28 dnl ==========================================================================
  29 dnl                               Versioning
  30 dnl ==========================================================================
  31
  32 dnl This is the package version number, not the shared library
  33 dnl version.  This same version number must appear in fontconfig/fontconfig.h
  34 dnl Yes, it is a pain to synchronize version numbers.  Unfortunately, it's
  35 dnl not possible to extract the version number here from fontconfig.h
  36 AM_INIT_AUTOMAKE(fontconfig, 2.2.92)
  37
  38 dnl libtool versioning
  39
  40 LT_CURRENT=1
  41 LT_REVISION=4
  42 AC_SUBST(LT_CURRENT)
  43 AC_SUBST(LT_REVISION)
  44 LT_AGE=0
  45
  46 LT_VERSION_INFO="$LT_CURRENT:$LT_REVISION:$LT_AGE"
  47 AC_SUBST(LT_VERSION_INFO)
  48
  49 LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
  50 AC_SUBST(LT_CURRENT_MINUS_AGE)
  51
  52 dnl ==========================================================================
  53
  54 AM_CONFIG_HEADER(config.h)
  55
  56 AC_PROG_CC
  57 AC_PROG_INSTALL
  58 AC_PROG_LN_S
  59 AC_LIBTOOL_WIN32_DLL
  60 AM_PROG_LIBTOOL
  61 AC_PROG_MAKE_SET
  62
  63 dnl ==========================================================================
  64
  65 case "$host" in
  66   *-*-mingw*)
  67     os_win32=yes
  68     ;;
  69   *)
  70     os_win32=no
  71 esac
  72 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
  73
  74 if test "$os_win32" = "yes"; then
  75   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
  76 fi
  77 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
  78
  79 dnl ==========================================================================
  80
  81 # Checks for header files.
  82 AC_HEADER_DIRENT
  83 AC_HEADER_STDC
  84 AC_CHECK_HEADERS([fcntl.h stdlib.h string.h unistd.h])
  85
  86 # Checks for typedefs, structures, and compiler characteristics.
  87 AC_C_CONST
  88 AC_TYPE_PID_T
  89
  90 # Checks for library functions.
  91 AC_FUNC_VPRINTF
  92 AC_CHECK_FUNCS([geteuid getuid link memmove memset mkstemp strchr strrchr strtol getopt getopt_long])
  93
  94 #
  95 # Checks for FreeType
  96 #
  97
  98 AC_ARG_WITH(freetype-config, [  --with-freetype-config=PROG   Use FreeType configuration program PROG], freetype_config=$withval, freetype_config=yes)
  99
 100 if test "$freetype_config" = "yes"; then
 101         AC_PATH_PROG(ft_config,freetype-config,no)
 102         if test "$ft_config" = "no"; then
 103                 AC_MSG_ERROR([You must have freetype installed; see http://www.freetype.org/])
 104         fi
 105 else
 106         ft_config="$freetype_config"
 107 fi
 108
 109 FREETYPE_CFLAGS="`$ft_config --cflags`"
 110 FREETYPE_LIBS="`$ft_config --libs`"
 111
 112 AC_SUBST(FREETYPE_LIBS)
 113 AC_SUBST(FREETYPE_CFLAGS)
 114
 115 #
 116 # Check to see whether we have:
 117 #  FT_Get_Next_Char
 118 #  FT_Get_BDF_Property
 119 #  FT_Get_PS_Font_Info
 120 #  FT_Has_PS_Glyph_Names
 121 #
 122
 123 fontconfig_save_libs="$LIBS"
 124 fontconfig_save_cflags="$CFLAGS"
 125 LIBS="$LIBS $FREETYPE_LIBS"
 126 CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
 127 AC_CHECK_FUNCS(FT_Get_Next_Char FT_Get_BDF_Property FT_Get_PS_Font_Info FT_Has_PS_Glyph_Names)
 128 AC_CHECK_MEMBER(FT_Bitmap_Size.y_ppem,
 129                 HAVE_FT_BITMAP_SIZE_Y_PPEM=1,
 130                 HAVE_FT_BITMAP_SIZE_Y_PPEM=0,
 131 [#include <ft2build.h>
 132 #include FT_FREETYPE_H])
 133 AC_DEFINE_UNQUOTED(HAVE_FT_BITMAP_SIZE_Y_PPEM,$HAVE_FT_BITMAP_SIZE_Y_PPEM,
 134                    [FT_Bitmap_Size structure includes y_ppem field])
 135
 136 #
 137 # Check expat configuration
 138 #
 139
 140 AC_ARG_WITH(expat,             [  --with-expat=DIR              Use Expat in DIR], expat=$withval, expat=yes)
 141 AC_ARG_WITH(expat-includes,    [  --with-expat-includes=DIR     Use Expat includes in DIR], expat_includes=$withval, expat_includes=yes)
 142 AC_ARG_WITH(expat-lib,         [  --with-expat-lib=DIR          Use Expat library in DIR], expat_lib=$withval, expat_lib=yes)
 143
 144 case "$expat" in
 145 no)
 146         ;;
 147 *)
 148         case "$expat_includes" in
 149         yes|no)
 150                 EXPAT_CFLAGS=""
 151                 ;;
 152         *)
 153                 EXPAT_CFLAGS="-I$expat_includes"
 154                 ;;
 155         esac
 156         case "$expat_lib" in
 157         yes)
 158                 case "$expat" in
 159                 yes)
 160                         EXPAT_LIBS="-lexpat"
 161                         ;;
 162                 *)
 163                         EXPAT_LIBS="-L$expat/lib -lexpat"
 164                         ;;
 165                 esac
 166                 ;;
 167         no)
 168                 ;;
 169         *)
 170                 EXPAT_LIBS="-L$expat_lib -lexpat"
 171                 ;;
 172         esac
 173
 174         expatsaved_CPPFLAGS="$CPPFLAGS"
 175         CPPFLAGS="$CPPFLAGS $EXPAT_CFLAGS"
 176         expatsaved_LIBS="$LIBS"
 177         LIBS="$LIBS $EXPAT_LIBS"
 178
 179         AC_CHECK_HEADER(expat.h)
 180         case "$ac_cv_header_expat_h" in
 181         no)
 182                 AC_CHECK_HEADER(xmlparse.h)
 183                 case "$ac_cv_header_xmlparse_h" in
 184                 no)
 185                         have_expat_header=no;
 186                         ;;
 187                 yes)
 188                         HAVE_XMLPARSE_H=1
 189                         AC_SUBST(HAVE_XMLPARSE_H)
 190                         AC_DEFINE_UNQUOTED(HAVE_XMLPARSE_H,$HAVE_XMLPARSE_H,
 191                         [Use xmlparse.h instead of expat.h])
 192                         have_expat_header=yes
 193                         ;;
 194                 esac
 195                 ;;
 196         yes)
 197                 have_expat_header=yes
 198                 ;;
 199         esac
 200         case "$have_expat_header" in
 201         no)
 202                 expat=no
 203                 ;;
 204         yes)
 205                 AC_CHECK_FUNCS(XML_SetDoctypeDeclHandler)
 206                 case "$ac_cv_func_XML_SetDoctypeDeclHandler" in
 207                 yes)
 208                         HAVE_EXPAT=1
 209                         AC_SUBST(HAVE_EXPAT)
 210                         AC_DEFINE_UNQUOTED(HAVE_EXPAT,$HAVE_EXPAT,
 211                         [Found a useable expat library])
 212                         ;;
 213                 *)
 214                         expat=no
 215                         ;;
 216                 esac
 217                 ;;
 218         esac
 219         CPPFLAGS="$expatsaved_CPPFLAGS"
 220         LIBS="$expatsaved_LIBS"
 221         ;;
 222 esac
 223 AC_SUBST(EXPAT_LIBS)
 224 AC_SUBST(EXPAT_CFLAGS)
 225
 226 case "$expat" in
 227 no)
 228         AC_MSG_ERROR([Cannot find usable expat library. This could mean that your version is too old.])
 229         ;;
 230 esac
 231
 232 #
 233 # Set default font directory
 234 #
 235
 236 AC_ARG_WITH(default-fonts,     [  --with-default-fonts=DIR      Use fonts from DIR when config is busted], default_fonts="$withval", default_fonts=yes)
 237
 238 case "$default_fonts" in
 239 yes)
 240         if test "$os_win32" = "yes"; then
 241                 FC_DEFAULT_FONTS="WINDOWSFONTDIR"
 242                 AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "WINDOWSFONTDIR",
 243                                    [Windows font directory])
 244         else
 245                 FC_DEFAULT_FONTS="/usr/share/fonts"
 246                 AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "/usr/share/fonts",
 247                                    [System font directory])
 248         fi
 249         ;;
 250 *)
 251         FC_DEFAULT_FONTS="$default_fonts"
 252         AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "$default_fonts",
 253                            [System font directory])
 254         ;;
 255 esac
 256
 257 AC_SUBST(FC_DEFAULT_FONTS)
 258
 259 #
 260 # Add more fonts if available.  By default, add only the directories
 261 # with outline fonts; those with bitmaps can be added as desired in
 262 # local.conf or ~/.fonts.conf
 263 #
 264 AC_ARG_WITH(add-fonts,        [  --with-add-fonts=DIR1,DIR2,...Find additional fonts in DIR1,DIR2,... ], add_fonts="$withval", add_fonts=yes)
 265
 266 case "$add_fonts" in
 267 yes)
 268         FC_ADD_FONTS=""
 269         for dir in /usr/X11R6/lib/X11 /usr/X11/lib/X11 /usr/lib/X11; do
 270                 case x"$FC_ADD_FONTS" in
 271                 x)
 272                         if test -d "$dir/fonts"; then
 273                                 for sub in "$dir"/fonts/*; do
 274                                         if ls "$sub" | grep -q -i '\.pf\|\.tt\|\.ot'; then
 275                                                 case x$FC_ADD_FONTS in
 276                                                 x)
 277                                                         FC_ADD_FONTS="$sub"
 278                                                         ;;
 279                                                 *)
 280                                                         FC_ADD_FONTS="$FC_ADD_FONTS,$sub"
 281                                                         ;;
 282                                                 esac
 283                                         fi
 284                                 done
 285                         fi
 286                         ;;
 287                 esac
 288         done
 289         AC_DEFINE_UNQUOTED(FC_ADD_FONTS,"$add_fonts",[Additional font directories])
 290         ;;
 291 no)
 292         FC_ADD_FONTS=""
 293         ;;
 294 *)
 295         FC_ADD_FONTS="$add_fonts"
 296         AC_DEFINE_UNQUOTED(FC_ADD_FONTS,"$add_fonts",[Additional font directories])
 297         ;;
 298 esac
 299
 300 AC_SUBST(FC_ADD_FONTS)
 301
 302 FC_FONTPATH=""
 303
 304 case "$FC_ADD_FONTS" in
 305 "")
 306         ;;
 307 *)
 308         FC_FONTPATH=`echo $FC_ADD_FONTS |
 309                         sed -e 's/^/<dir>/' -e 's/$/<\/dir>/' -e 's/,/<\/dir> <dir>/g'`
 310         ;;
 311 esac
 312
 313 AC_SUBST(FC_FONTPATH)
 314
 315 FC_FONTDATE=`date`
 316
 317 AC_SUBST(FC_FONTDATE)
 318
 319 AC_ARG_WITH(confdir,           [  --with-confdir=DIR            Use DIR to store configuration files (default /etc/fonts)], confdir="$withval", confdir=yes)
 320
 321 #
 322 # Set CONFDIR and FONTCONFIG_PATH
 323 #
 324
 325 case "$confdir" in
 326 no|yes)
 327         confdir='${sysconfdir}'/fonts
 328         ;;
 329 *)
 330         ;;
 331 esac
 332 AC_SUBST(confdir)
 333 CONFDIR=${confdir}
 334 AC_DEFINE_UNQUOTED(CONFDIR, "$CONFDIR",[Font configuration directory])
 335 AC_SUBST(CONFDIR)
 336
 337 #
 338 # Find out what language orthographies are included
 339 #
 340
 341 ORTH_FILES=`cd ${srcdir}/fc-lang && echo *.orth`
 342 AC_SUBST(ORTH_FILES)
 343
 344 #
 345 # Let people not build/install docs if they don't have docbook
 346 #
 347
 348 AC_CHECK_PROG(HASDOCBOOK, docbook2html, yes, no)
 349
 350 AM_CONDITIONAL(USEDOCBOOK, test "x$HASDOCBOOK" = xyes)
 351
 352 default_docs="yes"
 353 #
 354 # Check if docs exist or can be created
 355 #
 356 if test x$HASDOCBOOK = xno; then
 357         if test -f doc/fonts-conf.5; then
 358                 :
 359         else
 360                 default_docs="no"
 361         fi
 362 fi
 363
 364 AC_ARG_ENABLE(docs,           [  --disable-docs                Don't build and install documentation],,enable_docs=$default_docs)
 365
 366 AM_CONDITIONAL(ENABLE_DOCS, test "x$enable_docs" = xyes)
 367
 368 if test "x$enable_docs" = xyes; then
 369         DOCSRC="doc"
 370         tmp=funcs.$$
 371         cat $srcdir/doc/*.fncs | awk '
 372         /^@TITLE@/      { if (!done) { printf ("%s\n", $2); done = 1; } }
 373         /^@FUNC@/       { if (!done) { printf ("%s\n", $2); done = 1; } }
 374         /^@@/           { done = 0; }' > $tmp
 375         DOCMAN3=`cat $tmp | awk '{ printf ("%s.3 ", $1); }'`
 376         echo DOCMAN3 $DOCMAN3
 377         rm -f $tmp
 378 else
 379         DOCSRC=""
 380         DOCMAN3=""
 381 fi
 382
 383 AC_SUBST(DOCSRC)
 384 AC_SUBST(DOCMAN3)
 385
 386 #
 387 # Figure out where to install documentation
 388 #
 389
 390 AC_ARG_WITH(docdir,           [  --with-docdir=DIR             Use DIR to store documentation files (default ${datadir}/doc/fontconfig)], confdir="$withval")
 391
 392 if test "x$with_docdir" = "x" ; then
 393   DOCDIR='${datadir}/doc/fontconfig'
 394 else
 395   DOCDIR=$with_docdir
 396 fi
 397
 398 AC_SUBST(DOCDIR)
 399
 400 AC_OUTPUT([
 401 Makefile
 402 fontconfig/Makefile
 403 fc-lang/Makefile
 404 fc-glyphname/Makefile
 405 src/Makefile
 406 src/fontconfig.def
 407 fc-cache/Makefile
 408 fc-list/Makefile
 409 fc-match/Makefile
 410 doc/Makefile
 411 doc/version.sgml
 412 test/Makefile
 413 fontconfig.spec
 414 fontconfig.pc
 415 fonts.conf
 416 fontconfig-zip
 417 ])