configure.in

   1 dnl
   2 dnl  $Id$
   3 dnl
   4 dnl  Copyright © 2003 Keith Packard
   5 dnl
   6 dnl  Permission to use, copy, modify, distribute, and sell this software and its
   7 dnl  documentation for any purpose is hereby granted without fee, provided that
   8 dnl  the above copyright notice appear in all copies and that both that
   9 dnl  copyright notice and this permission notice appear in supporting
  10 dnl  documentation, and that the name of Keith Packard not be used in
  11 dnl  advertising or publicity pertaining to distribution of the software without
  12 dnl  specific, written prior permission.  Keith Packard makes no
  13 dnl  representations about the suitability of this software for any purpose.  It
  14 dnl  is provided "as is" without express or implied warranty.
  15 dnl
  16 dnl  KEITH PACKARD DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
  17 dnl  INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
  18 dnl  EVENT SHALL KEITH PACKARD BE LIABLE FOR ANY SPECIAL, INDIRECT OR
  19 dnl  CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
  20 dnl  DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
  21 dnl  TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
  22 dnl  PERFORMANCE OF THIS SOFTWARE.
  23 dnl
  24 dnl Process this file with autoconf to create configure.
  25
  26 AC_INIT(fonts.dtd)
  27
  28 dnl ==========================================================================
  29 dnl                               Versioning
  30 dnl ==========================================================================
  31
  32 dnl This is the package version number, not the shared library
  33 dnl version.  This same version number must appear in fontconfig/fontconfig.h
  34 dnl Yes, it is a pain to synchronize version numbers.  Unfortunately, it's
  35 dnl not possible to extract the version number here from fontconfig.h
  36 AM_INIT_AUTOMAKE(fontconfig, 2.2.0)
  37
  38 dnl libtool versioning
  39
  40 LT_CURRENT=1
  41 LT_REVISION=4
  42 AC_SUBST(LT_CURRENT)
  43 AC_SUBST(LT_REVISION)
  44 LT_AGE=0
  45
  46 LT_VERSION_INFO="$LT_CURRENT:$LT_REVISION:$LT_AGE"
  47 AC_SUBST(LT_VERSION_INFO)
  48
  49 LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
  50 AC_SUBST(LT_CURRENT_MINUS_AGE)
  51
  52 dnl ==========================================================================
  53
  54 AM_CONFIG_HEADER(config.h)
  55
  56 AC_PROG_CC
  57 AC_PROG_INSTALL
  58 AC_PROG_LN_S
  59 AC_LIBTOOL_WIN32_DLL
  60 AM_PROG_LIBTOOL
  61 AC_PROG_MAKE_SET
  62
  63 dnl ==========================================================================
  64
  65 case "$host" in
  66   *-*-mingw*)
  67     os_win32=yes
  68     ;;
  69   *)
  70     os_win32=no
  71 esac
  72 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
  73
  74 if test "$os_win32" = "yes"; then
  75   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
  76 fi
  77 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
  78
  79 dnl ==========================================================================
  80
  81 # Checks for header files.
  82 AC_HEADER_DIRENT
  83 AC_HEADER_STDC
  84 AC_CHECK_HEADERS([fcntl.h stdlib.h string.h unistd.h])
  85
  86 # Checks for typedefs, structures, and compiler characteristics.
  87 AC_C_CONST
  88 AC_TYPE_PID_T
  89
  90 # Checks for library functions.
  91 AC_FUNC_VPRINTF
  92 AC_CHECK_FUNCS([geteuid getuid link memmove memset mkstemp strchr strrchr strtol getopt getopt_long])
  93
  94 #
  95 # Checks for FreeType
  96 #
  97
  98 AC_ARG_WITH(freetype-config, [  --with-freetype-config=PROG   Use FreeType configuration program PROG], freetype_config=$withval, freetype_config=yes)
  99
 100 if test "$freetype_config" = "yes"; then
 101         AC_PATH_PROG(ft_config,freetype-config,no)
 102         if test "$ft_config" = "no"; then
 103                 AC_MSG_ERROR([You must have freetype installed; see http://www.freetype.org/])
 104         fi
 105 else
 106         ft_config="$freetype_config"
 107 fi
 108
 109 FREETYPE_CFLAGS="`$ft_config --cflags`"
 110 FREETYPE_LIBS="`$ft_config --libs`"
 111
 112 AC_SUBST(FREETYPE_LIBS)
 113 AC_SUBST(FREETYPE_CFLAGS)
 114
 115 #
 116 # Check to see whether we have FT_Get_First_Char(), new in 2.0.9
 117 #
 118
 119 fontconfig_save_libs=$LIBS
 120 LIBS="$LIBS $FREETYPE_LIBS"
 121 AC_CHECK_FUNCS(FT_Get_First_Char)
 122 LIBS=$fontconfig_save_libs
 123
 124 #
 125 # Check expat configuration
 126 #
 127
 128 AC_ARG_WITH(expat,             [  --with-expat=DIR              Use Expat in DIR], expat=$withval, expat=yes)
 129 AC_ARG_WITH(expat-includes,    [  --with-expat-includes=DIR     Use Expat includes in DIR], expat_includes=$withval, expat_includes=yes)
 130 AC_ARG_WITH(expat-lib,         [  --with-expat-lib=DIR          Use Expat library in DIR], expat_lib=$withval, expat_lib=yes)
 131
 132 case "$expat" in
 133 no)
 134         ;;
 135 *)
 136         case "$expat_includes" in
 137         yes|no)
 138                 EXPAT_CFLAGS=""
 139                 ;;
 140         *)
 141                 EXPAT_CFLAGS="-I$expat_includes"
 142                 ;;
 143         esac
 144         case "$expat_lib" in
 145         yes)
 146                 case "$expat" in
 147                 yes)
 148                         EXPAT_LIBS="-lexpat"
 149                         ;;
 150                 *)
 151                         EXPAT_LIBS="-L$expat/lib -lexpat"
 152                         ;;
 153                 esac
 154                 ;;
 155         no)
 156                 ;;
 157         *)
 158                 EXPAT_LIBS="-L$expat_lib -lexpat"
 159                 ;;
 160         esac
 161
 162         expatsaved_CPPFLAGS="$CPPFLAGS"
 163         CPPFLAGS="$CPPFLAGS $EXPAT_CFLAGS"
 164         expatsaved_LIBS="$LIBS"
 165         LIBS="$LIBS $EXPAT_LIBS"
 166
 167         AC_CHECK_HEADER(expat.h)
 168         case "$ac_cv_header_expat_h" in
 169         no)
 170                 AC_CHECK_HEADER(xmlparse.h)
 171                 case "$ac_cv_header_xmlparse_h" in
 172                 no)
 173                         have_expat_header=no;
 174                         ;;
 175                 yes)
 176                         HAVE_XMLPARSE_H=1
 177                         AC_SUBST(HAVE_XMLPARSE_H)
 178                         AC_DEFINE_UNQUOTED(HAVE_XMLPARSE_H,$HAVE_XMLPARSE_H,
 179                         [Use xmlparse.h instead of expat.h])
 180                         have_expat_header=yes
 181                         ;;
 182                 esac
 183                 ;;
 184         yes)
 185                 have_expat_header=yes
 186                 ;;
 187         esac
 188         case "$have_expat_header" in
 189         no)
 190                 expat=no
 191                 ;;
 192         yes)
 193                 AC_CHECK_FUNCS(XML_ParserCreate)
 194                 case "$ac_cv_func_XML_ParserCreate" in
 195                 no)
 196                         expat=no
 197                         ;;
 198                 yes)
 199                         HAVE_EXPAT=1
 200                         AC_SUBST(HAVE_EXPAT)
 201                         AC_DEFINE_UNQUOTED(HAVE_EXPAT,$HAVE_EXPAT,
 202                         [Found a useable expat library])
 203                         ;;
 204                 esac
 205                 ;;
 206         esac
 207         CPPFLAGS="$expatsaved_CPPFLAGS"
 208         LIBS="$expatsaved_LIBS"
 209         ;;
 210 esac
 211 AC_SUBST(EXPAT_LIBS)
 212 AC_SUBST(EXPAT_CFLAGS)
 213
 214 case "$expat" in
 215 no)
 216         AC_MSG_ERROR([cannot find expat library])
 217         ;;
 218 esac
 219
 220 #
 221 # Set default font directory
 222 #
 223
 224 AC_ARG_WITH(default-fonts,     [  --with-default-fonts=DIR      Use fonts from DIR when config is busted], default_fonts="$withval", default_fonts=yes)
 225
 226 case "$default_fonts" in
 227 yes)
 228         FC_DEFAULT_FONTS="/usr/share/fonts"
 229         AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "/usr/share/fonts",
 230                            [System font directory])
 231         ;;
 232 *)
 233         FC_DEFAULT_FONTS="$default_fonts"
 234         AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "$default_fonts",
 235                            [System font directory])
 236         ;;
 237 esac
 238
 239 AC_SUBST(FC_DEFAULT_FONTS)
 240
 241 #
 242 # Add more fonts if available.  By default, add only the directories
 243 # with outline fonts; those with bitmaps can be added as desired in
 244 # local.conf or ~/.fonts.conf
 245 #
 246 AC_ARG_WITH(add-fonts,        [  --with-add-fonts=DIR1,DIR2,...Find additional fonts in DIR1,DIR2,... ], add_fonts="$withval", add_fonts=yes)
 247
 248 case "$add_fonts" in
 249 yes)
 250         FC_ADD_FONTS=""
 251         for dir in /usr/X11R6/lib/X11 /usr/X11/lib/X11 /usr/lib/X11; do
 252                 case x"$FC_ADD_FONTS" in
 253                 x)
 254                         if test -d "$dir/fonts"; then
 255                                 for sub in "$dir"/fonts/*; do
 256                                         if ls "$sub" | grep -q -i '\.pf\|\.tt\|\.ot'; then
 257                                                 case x$FC_ADD_FONTS in
 258                                                 x)
 259                                                         FC_ADD_FONTS="$sub"
 260                                                         ;;
 261                                                 *)
 262                                                         FC_ADD_FONTS="$FC_ADD_FONTS,$sub"
 263                                                         ;;
 264                                                 esac
 265                                         fi
 266                                 done
 267                         fi
 268                         ;;
 269                 esac
 270         done
 271         AC_DEFINE_UNQUOTED(FC_ADD_FONTS,"$add_fonts",[Additional font directories])
 272         ;;
 273 no)
 274         FC_ADD_FONTS=""
 275         ;;
 276 *)
 277         FC_ADD_FONTS="$add_fonts"
 278         AC_DEFINE_UNQUOTED(FC_ADD_FONTS,"$add_fonts",[Additional font directories])
 279         ;;
 280 esac
 281
 282 AC_SUBST(FC_ADD_FONTS)
 283
 284 FC_FONTPATH=""
 285
 286 case "$FC_ADD_FONTS" in
 287 "")
 288         ;;
 289 *)
 290         FC_FONTPATH=`echo $FC_ADD_FONTS |
 291                         sed -e 's/^/<dir>/' -e 's/$/<\/dir>/' -e 's/,/<\/dir> <dir>/g'`
 292         ;;
 293 esac
 294
 295 AC_SUBST(FC_FONTPATH)
 296
 297 FC_FONTDATE=`date`
 298
 299 AC_SUBST(FC_FONTDATE)
 300
 301 AC_ARG_WITH(confdir,           [  --with-confdir=DIR            Use DIR to store configuration files (default /etc/fonts)], confdir="$withval", confdir=yes)
 302
 303 #
 304 # Set CONFDIR and FONTCONFIG_PATH
 305 #
 306
 307 case "$confdir" in
 308 no|yes)
 309         confdir='${sysconfdir}'/fonts
 310         ;;
 311 *)
 312         ;;
 313 esac
 314 AC_SUBST(confdir)
 315 CONFDIR=${confdir}
 316 AC_DEFINE_UNQUOTED(CONFDIR, "$CONFDIR",[Font configuration directory])
 317 AC_SUBST(CONFDIR)
 318
 319 #
 320 # Find out what language orthographies are included
 321 #
 322
 323 ORTH_FILES=`cd fc-lang && echo *.orth`
 324 AC_SUBST(ORTH_FILES)
 325
 326 #
 327 # Let people not build/install docs if they don't have docbook
 328 #
 329
 330 AC_CHECK_PROG(HASDOCBOOK, docbook2html, yes, no)
 331
 332 AC_ARG_ENABLE(docs,           [  --disable-docs                Don't build and install documentation],,enable_docs=yes)
 333
 334 if test "x$enable_docs" = xyes; then
 335   if test "x$HASDOCBOOK" != xyes; then
 336     enable_docs=no
 337   fi
 338 fi
 339
 340 AM_CONDITIONAL(ENABLE_DOCS, test "x$enable_docs" = xyes)
 341
 342 #
 343 # Figure out where to install documentation
 344 #
 345
 346 AC_ARG_WITH(docdir,           [  --with-docdir=DIR             Use DIR to store documentation files (default ${datadir}/doc/fontconfig)], confdir="$withval")
 347
 348 if test "x$with_docdir" = "x" ; then
 349   DOCDIR='${datadir}/doc/fontconfig'
 350 else
 351   DOCDIR=$with_docdir
 352 fi
 353
 354 AC_SUBST(DOCDIR)
 355
 356 AC_OUTPUT([
 357 Makefile
 358 fontconfig/Makefile
 359 fc-lang/Makefile
 360 src/Makefile
 361 src/fontconfig.def
 362 fc-cache/Makefile
 363 fc-list/Makefile
 364 doc/Makefile
 365 doc/version.sgml
 366 doc/confdir.sgml
 367 test/Makefile
 368 fontconfig.spec
 369 fontconfig.pc
 370 fonts.conf
 371 fontconfig-zip
 372 ])