configure.in

   1 dnl
   2 dnl  $Id$
   3 dnl
   4 dnl  Copyright © 2003 Keith Packard
   5 dnl
   6 dnl  Permission to use, copy, modify, distribute, and sell this software and its
   7 dnl  documentation for any purpose is hereby granted without fee, provided that
   8 dnl  the above copyright notice appear in all copies and that both that
   9 dnl  copyright notice and this permission notice appear in supporting
  10 dnl  documentation, and that the name of Keith Packard not be used in
  11 dnl  advertising or publicity pertaining to distribution of the software without
  12 dnl  specific, written prior permission.  Keith Packard makes no
  13 dnl  representations about the suitability of this software for any purpose.  It
  14 dnl  is provided "as is" without express or implied warranty.
  15 dnl
  16 dnl  KEITH PACKARD DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
  17 dnl  INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
  18 dnl  EVENT SHALL KEITH PACKARD BE LIABLE FOR ANY SPECIAL, INDIRECT OR
  19 dnl  CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
  20 dnl  DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
  21 dnl  TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
  22 dnl  PERFORMANCE OF THIS SOFTWARE.
  23 dnl
  24 dnl Process this file with autoconf to create configure.
  25
  26 AC_INIT(fonts.dtd)
  27
  28 dnl ==========================================================================
  29 dnl                               Versioning
  30 dnl ==========================================================================
  31
  32 dnl This is the package version number, not the shared library
  33 dnl version.  This same version number must appear in fontconfig/fontconfig.h
  34 dnl Yes, it is a pain to synchronize version numbers.  Unfortunately, it's
  35 dnl not possible to extract the version number here from fontconfig.h
  36 AM_INIT_AUTOMAKE(fontconfig, 2.3.95)
  37 AM_MAINTAINER_MODE
  38
  39 dnl libtool versioning
  40
  41 LT_CURRENT=1
  42 LT_REVISION=4
  43 AC_SUBST(LT_CURRENT)
  44 AC_SUBST(LT_REVISION)
  45 LT_AGE=0
  46
  47 LT_VERSION_INFO="$LT_CURRENT:$LT_REVISION:$LT_AGE"
  48 AC_SUBST(LT_VERSION_INFO)
  49
  50 LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
  51 AC_SUBST(LT_CURRENT_MINUS_AGE)
  52
  53 dnl ==========================================================================
  54
  55 AM_CONFIG_HEADER(config.h)
  56
  57 AC_PROG_CC
  58 AC_PROG_INSTALL
  59 AC_PROG_LN_S
  60 AC_LIBTOOL_WIN32_DLL
  61 AM_PROG_LIBTOOL
  62 AC_PROG_MAKE_SET
  63
  64 dnl ==========================================================================
  65
  66 case "$host" in
  67   *-*-mingw*)
  68     os_win32=yes
  69     ;;
  70   *)
  71     os_win32=no
  72 esac
  73 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
  74
  75 if test "$os_win32" = "yes"; then
  76   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
  77 fi
  78 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
  79
  80 WARN_CFLAGS=""
  81
  82 if test "x$GCC" = "xyes"; then
  83         WARN_CFLAGS="-Wall -Wpointer-arith -Wstrict-prototypes \
  84         -Wmissing-prototypes -Wmissing-declarations \
  85         -Wnested-externs -fno-strict-aliasing"
  86 fi
  87 AC_SUBST(WARN_CFLAGS)
  88
  89 dnl ==========================================================================
  90
  91 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
  92
  93 dnl ==========================================================================
  94
  95 # Setup for compiling build tools (fc-glyphname, etc)
  96 AC_MSG_CHECKING([for a C compiler for build tools])
  97 if test $cross_compiling = yes; then
  98   AC_CHECK_PROGS(CC_FOR_BUILD, gcc cc)
  99 else
 100   CC_FOR_BUILD=$CC
 101 fi
 102 AC_MSG_RESULT([$CC_FOR_BUILD])
 103 AC_SUBST(CC_FOR_BUILD)
 104
 105 AC_MSG_CHECKING([for suffix of executable build tools])
 106 if test $cross_compiling = yes; then
 107   cat >conftest.c <<\_______EOF
 108 int
 109 main ()
 110 {
 111   exit (0);
 112 }
 113 _______EOF
 114   for i in .exe ""; do
 115     compile="$CC_FOR_BUILD conftest.c -o conftest$i"
 116     if AC_TRY_EVAL(compile); then
 117       if (./conftest) 2>&AC_FD_CC; then
 118         EXEEXT_FOR_BUILD=$i
 119         break
 120       fi
 121     fi
 122   done
 123   rm -f conftest*
 124   if test "${EXEEXT_FOR_BUILD+set}" != set; then
 125     AC_MSG_ERROR([Cannot determine suffix of executable build tools])
 126   fi
 127 else
 128   EXEEXT_FOR_BUILD=$EXEEXT
 129 fi
 130 AC_MSG_RESULT([$EXEEXT_FOR_BUILD])
 131 AC_SUBST(EXEEXT_FOR_BUILD)
 132
 133 dnl ==========================================================================
 134
 135 AC_ARG_WITH(arch,      [  --with-arch=ARCH      Force architecture to ARCH], arch="$withval", arch=auto)
 136
 137 if test $cross_compiling = yes; then
 138         case "$arch" in
 139         auto)
 140                 AC_MSG_ERROR([Cannot autodetect architecture in cross compile environment]
 141                              [Use --with-arch=ARCH to specify architecture])
 142                 ;;
 143         esac
 144 fi
 145
 146 ARCHITECTURE=$arch
 147 AC_SUBST(ARCHITECTURE)
 148
 149 dnl ==========================================================================
 150
 151 # Checks for header files.
 152 AC_HEADER_DIRENT
 153 AC_HEADER_STDC
 154 AC_CHECK_HEADERS([fcntl.h stdlib.h string.h unistd.h])
 155
 156 # Checks for typedefs, structures, and compiler characteristics.
 157 AC_C_CONST
 158 AC_C_INLINE
 159 AC_TYPE_PID_T
 160
 161 # Checks for library functions.
 162 AC_FUNC_VPRINTF
 163 AC_FUNC_MMAP
 164 AC_CHECK_FUNCS([geteuid getuid link memmove memset mkstemp strchr strrchr strtol getopt getopt_long sysconf ftruncate chsize rand_r])
 165
 166 #
 167 # Checks for iconv
 168 #
 169 AC_MSG_CHECKING([for a usable iconv])
 170 ICONV_LIBS=""
 171 AC_TRY_LINK([#include <iconv.h>],
 172             [iconv_open ("from", "to");],
 173             [use_iconv=1],
 174             [use_iconv=0])
 175 if test x$use_iconv = x1; then
 176         AC_MSG_RESULT([libc])
 177 else
 178         # try using libiconv
 179         fontconfig_save_libs="$LIBS"
 180         LIBS="$LIBS -liconv"
 181
 182         AC_TRY_LINK([#include <iconv.h>],
 183                     [iconv_open ("from", "to");],
 184                     [use_iconv=true],
 185                     [use_iconv=false])
 186
 187         if test x$use_iconv = x1; then
 188                 ICONV_LIBS="-liconv"
 189                 AC_MSG_RESULT([libiconv])
 190         else
 191                 AC_MSG_RESULT([no])
 192         fi
 193
 194         LIBS="$fontconfig_save_libs"
 195 fi
 196 AC_SUBST(ICONV_LIBS)
 197 AC_DEFINE_UNQUOTED(USE_ICONV,$use_iconv,[Use iconv.])
 198
 199 #
 200 # Checks for FreeType
 201 #
 202
 203 AC_ARG_WITH(freetype-config, [  --with-freetype-config=PROG   Use FreeType configuration program PROG], freetype_config=$withval, freetype_config=yes)
 204
 205 if test "$freetype_config" = "yes"; then
 206         AC_PATH_PROG(ft_config,freetype-config,no)
 207         if test "$ft_config" = "no"; then
 208                 AC_MSG_ERROR([You must have freetype installed; see http://www.freetype.org/])
 209         fi
 210 else
 211         ft_config="$freetype_config"
 212 fi
 213
 214 FREETYPE_CFLAGS="`$ft_config --cflags`"
 215 FREETYPE_LIBS="`$ft_config --libs`"
 216
 217 AC_SUBST(FREETYPE_LIBS)
 218 AC_SUBST(FREETYPE_CFLAGS)
 219
 220 #
 221 # Check to see whether we have:
 222 #  FT_Get_Next_Char
 223 #  FT_Get_BDF_Property
 224 #  FT_Get_PS_Font_Info
 225 #  FT_Has_PS_Glyph_Names
 226 #
 227
 228 fontconfig_save_libs="$LIBS"
 229 fontconfig_save_cflags="$CFLAGS"
 230 LIBS="$LIBS $FREETYPE_LIBS"
 231 CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
 232 AC_CHECK_FUNCS(FT_Get_Next_Char FT_Get_BDF_Property FT_Get_PS_Font_Info FT_Has_PS_Glyph_Names FT_Get_X11_Font_Format)
 233 AC_CHECK_MEMBER(FT_Bitmap_Size.y_ppem,
 234                 HAVE_FT_BITMAP_SIZE_Y_PPEM=1,
 235                 HAVE_FT_BITMAP_SIZE_Y_PPEM=0,
 236 [#include <ft2build.h>
 237 #include FT_FREETYPE_H])
 238 AC_DEFINE_UNQUOTED(HAVE_FT_BITMAP_SIZE_Y_PPEM,$HAVE_FT_BITMAP_SIZE_Y_PPEM,
 239                    [FT_Bitmap_Size structure includes y_ppem field])
 240 CFLAGS="$fontconfig_save_cflags"
 241 LIBS="$fontconfig_save_libs"
 242
 243 #
 244 # Check expat configuration
 245 #
 246
 247 AC_ARG_WITH(expat,             [  --with-expat=DIR              Use Expat in DIR], expat=$withval, expat=yes)
 248 AC_ARG_WITH(expat-includes,    [  --with-expat-includes=DIR     Use Expat includes in DIR], expat_includes=$withval, expat_includes=yes)
 249 AC_ARG_WITH(expat-lib,         [  --with-expat-lib=DIR          Use Expat library in DIR], expat_lib=$withval, expat_lib=yes)
 250
 251 if test "$enable_libxml2" != "yes"; then
 252         case "$expat" in
 253         no)
 254         ;;
 255         *)
 256                 case "$expat_includes" in
 257                 yes)
 258                         case "$expat" in
 259                         yes)
 260                                 ;;
 261                         *)
 262                                 EXPAT_CFLAGS="-I$expat/include"
 263                                 ;;
 264                         esac
 265                         ;;
 266                 no)
 267                         EXPAT_CFLAGS=""
 268                         ;;
 269                 *)
 270                         EXPAT_CFLAGS="-I$expat_includes"
 271                         ;;
 272                 esac
 273                 case "$expat_lib" in
 274                 yes)
 275                         case "$expat" in
 276                         yes)
 277                                 EXPAT_LIBS="-lexpat"
 278                                 ;;
 279                         *)
 280                                 EXPAT_LIBS="-L$expat/lib -lexpat"
 281                                 ;;
 282                         esac
 283                         ;;
 284                 no)
 285                         ;;
 286                 *)
 287                         EXPAT_LIBS="-L$expat_lib -lexpat"
 288                         ;;
 289                 esac
 290
 291                 expatsaved_CPPFLAGS="$CPPFLAGS"
 292                 CPPFLAGS="$CPPFLAGS $EXPAT_CFLAGS"
 293                 expatsaved_LIBS="$LIBS"
 294                 LIBS="$LIBS $EXPAT_LIBS"
 295
 296                 AC_CHECK_HEADER(expat.h)
 297                 case "$ac_cv_header_expat_h" in
 298                 no)
 299                         AC_CHECK_HEADER(xmlparse.h)
 300                         case "$ac_cv_header_xmlparse_h" in
 301                         no)
 302                                 have_expat_header=no;
 303                                 ;;
 304                         yes)
 305                                 HAVE_XMLPARSE_H=1
 306                                 AC_SUBST(HAVE_XMLPARSE_H)
 307                                 AC_DEFINE_UNQUOTED(HAVE_XMLPARSE_H,$HAVE_XMLPARSE_H,
 308                                 [Use xmlparse.h instead of expat.h])
 309                                 have_expat_header=yes
 310                                 ;;
 311                         esac
 312                         ;;
 313                 yes)
 314                         have_expat_header=yes
 315                         ;;
 316                 esac
 317                 case "$have_expat_header" in
 318                 no)
 319                         expat=no
 320                         ;;
 321                 yes)
 322                         AC_CHECK_FUNCS(XML_SetDoctypeDeclHandler)
 323                         case "$ac_cv_func_XML_SetDoctypeDeclHandler" in
 324                         yes)
 325                                 HAVE_EXPAT=1
 326                                 AC_SUBST(HAVE_EXPAT)
 327                                 AC_DEFINE_UNQUOTED(HAVE_EXPAT,$HAVE_EXPAT,
 328                                 [Found a useable expat library])
 329                                 ;;
 330                         *)
 331                                 expat=no
 332                                 ;;
 333                         esac
 334                         ;;
 335                 esac
 336                 CPPFLAGS="$expatsaved_CPPFLAGS"
 337                 LIBS="$expatsaved_LIBS"
 338                 ;;
 339         esac
 340
 341         AC_SUBST(EXPAT_CFLAGS)
 342         AC_SUBST(EXPAT_LIBS)
 343
 344         case "$expat" in
 345         no)
 346                 EXPAT_CFLAGS=""
 347                 EXPAT_LIBS=""
 348
 349                 AC_MSG_WARN([Cannot find usable expat library. Trying to use libxml2 as fallback.])
 350                 ;;
 351         esac
 352 fi
 353
 354 #
 355 # Check libxml2 configuration
 356 #
 357
 358 AC_ARG_ENABLE(libxml2,         [  --enable-libxml2              Use libxml2 instead of Expat])
 359
 360 PKG_PROG_PKG_CONFIG
 361
 362 if test "$enable_libxml2" = "yes" -o "$expat" = "no"; then
 363     PKG_CHECK_MODULES([LIBXML2], [libxml-2.0 >= 2.6])
 364     AC_DEFINE_UNQUOTED(ENABLE_LIBXML2,1,[Use libxml2 instead of Expat])
 365
 366     AC_SUBST(LIBXML2_CFLAGS)
 367     AC_SUBST(LIBXML2_LIBS)
 368 fi
 369
 370 #
 371 # Set default font directory
 372 #
 373
 374 AC_ARG_WITH(default-fonts,     [  --with-default-fonts=DIR      Use fonts from DIR when config is busted], default_fonts="$withval", default_fonts=yes)
 375
 376 case "$default_fonts" in
 377 yes)
 378         if test "$os_win32" = "yes"; then
 379                 FC_DEFAULT_FONTS="WINDOWSFONTDIR"
 380                 AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "WINDOWSFONTDIR",
 381                                    [Windows font directory])
 382         else
 383                 FC_DEFAULT_FONTS="/usr/share/fonts"
 384                 AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "/usr/share/fonts",
 385                                    [System font directory])
 386         fi
 387         ;;
 388 *)
 389         FC_DEFAULT_FONTS="$default_fonts"
 390         AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "$default_fonts",
 391                            [System font directory])
 392         ;;
 393 esac
 394
 395 AC_SUBST(FC_DEFAULT_FONTS)
 396
 397 #
 398 # Add more fonts if available.  By default, add only the directories
 399 # with outline fonts; those with bitmaps can be added as desired in
 400 # local.conf or ~/.fonts.conf
 401 #
 402 AC_ARG_WITH(add-fonts,        [  --with-add-fonts=DIR1,DIR2,...Find additional fonts in DIR1,DIR2,... ], add_fonts="$withval", add_fonts=yes)
 403
 404 case "$add_fonts" in
 405 yes)
 406         FC_ADD_FONTS=""
 407         for dir in /usr/X11R6/lib/X11 /usr/X11/lib/X11 /usr/lib/X11; do
 408                 case x"$FC_ADD_FONTS" in
 409                 x)
 410                         sub="$dir/fonts"
 411                         if test -d "$sub"; then
 412                                 case x$FC_ADD_FONTS in
 413                                 x)
 414                                         FC_ADD_FONTS="$sub"
 415                                         ;;
 416                                 *)
 417                                         FC_ADD_FONTS="$FC_ADD_FONTS,$sub"
 418                                         ;;
 419                                 esac
 420                         fi
 421                         ;;
 422                 esac
 423         done
 424         AC_DEFINE_UNQUOTED(FC_ADD_FONTS,"$add_fonts",[Additional font directories])
 425         ;;
 426 no)
 427         FC_ADD_FONTS=""
 428         ;;
 429 *)
 430         FC_ADD_FONTS="$add_fonts"
 431         AC_DEFINE_UNQUOTED(FC_ADD_FONTS,"$add_fonts",[Additional font directories])
 432         ;;
 433 esac
 434
 435 AC_SUBST(FC_ADD_FONTS)
 436
 437 FC_FONTPATH=""
 438
 439 case "$FC_ADD_FONTS" in
 440 "")
 441         ;;
 442 *)
 443         FC_FONTPATH=`echo $FC_ADD_FONTS |
 444                         sed -e 's/^/<dir>/' -e 's/$/<\/dir>/' -e 's/,/<\/dir> <dir>/g'`
 445         ;;
 446 esac
 447
 448 AC_SUBST(FC_FONTPATH)
 449
 450 #
 451 # Set default cache directory path
 452 #
 453 AC_ARG_WITH(cache-dir,         [ --with-cache-dir=DIR           Use DIR to store cache files (default /var/cache/fontconfig)], fc_cachedir="$withval", fc_cachedir=yes)
 454
 455 case $fc_cachedir in
 456 no|yes)
 457         fc_cachedir=`eval echo "${localstatedir}/cache/"${PACKAGE}`
 458         ;;
 459 *)
 460         ;;
 461 esac
 462 AC_SUBST(fc_cachedir)
 463 FC_CACHEDIR=${fc_cachedir}
 464 AC_SUBST(FC_CACHEDIR)
 465
 466 FC_FONTDATE=`LC_ALL=C date`
 467
 468 AC_SUBST(FC_FONTDATE)
 469
 470 AC_ARG_WITH(confdir,           [  --with-confdir=DIR            Use DIR to store configuration files (default /etc/fonts)], confdir="$withval", confdir=yes)
 471
 472 #
 473 # Set CONFDIR and FONTCONFIG_PATH
 474 #
 475
 476 case "$confdir" in
 477 no|yes)
 478         confdir='${sysconfdir}'/fonts
 479         ;;
 480 *)
 481         ;;
 482 esac
 483 AC_SUBST(confdir)
 484 CONFDIR=${confdir}
 485 AC_DEFINE_UNQUOTED(CONFDIR, "$CONFDIR",[Font configuration directory])
 486 AC_SUBST(CONFDIR)
 487
 488 #
 489 # Find out what language orthographies are included
 490 #
 491
 492 ORTH_FILES=`cd ${srcdir}/fc-lang && echo *.orth`
 493 AC_SUBST(ORTH_FILES)
 494
 495 #
 496 # Let people not build/install docs if they don't have docbook
 497 #
 498
 499 AC_CHECK_PROG(HASDOCBOOK, docbook2html, yes, no)
 500
 501 AM_CONDITIONAL(USEDOCBOOK, test "x$HASDOCBOOK" = xyes)
 502
 503 default_docs="yes"
 504 #
 505 # Check if docs exist or can be created
 506 #
 507 if test x$HASDOCBOOK = xno; then
 508         if test -f doc/fonts-conf.5; then
 509                 :
 510         else
 511                 default_docs="no"
 512         fi
 513 fi
 514
 515 AC_ARG_ENABLE(docs,           [  --disable-docs                Don't build and install documentation],,enable_docs=$default_docs)
 516
 517 AM_CONDITIONAL(ENABLE_DOCS, test "x$enable_docs" = xyes)
 518
 519 if test "x$enable_docs" = xyes; then
 520         DOCSRC="doc"
 521         tmp=funcs.$$
 522         cat $srcdir/doc/*.fncs | awk '
 523         /^@TITLE@/      { if (!done) { printf ("%s\n", $2); done = 1; } }
 524         /^@FUNC@/       { if (!done) { printf ("%s\n", $2); done = 1; } }
 525         /^@@/           { done = 0; }' > $tmp
 526         DOCMAN3=`cat $tmp | awk '{ printf ("%s.3 ", $1); }'`
 527         echo DOCMAN3 $DOCMAN3
 528         rm -f $tmp
 529 else
 530         DOCSRC=""
 531         DOCMAN3=""
 532 fi
 533
 534 AC_SUBST(DOCSRC)
 535 AC_SUBST(DOCMAN3)
 536
 537 #
 538 # Figure out where to install documentation
 539 #
 540
 541 AC_ARG_WITH(docdir,           [  --with-docdir=DIR             Use DIR to store documentation files (default ${datadir}/doc/fontconfig)], confdir="$withval")
 542
 543 if test "x$with_docdir" = "x" ; then
 544   DOCDIR='${datadir}/doc/fontconfig'
 545 else
 546   DOCDIR=$with_docdir
 547 fi
 548
 549 AC_SUBST(DOCDIR)
 550
 551
 552 AC_OUTPUT([
 553 Makefile
 554 fontconfig/Makefile
 555 fc-lang/Makefile
 556 fc-glyphname/Makefile
 557 fc-case/Makefile
 558 fc-arch/Makefile
 559 src/Makefile
 560 src/fontconfig.def
 561 conf.d/Makefile
 562 fc-cache/Makefile
 563 fc-cat/Makefile
 564 fc-list/Makefile
 565 fc-match/Makefile
 566 doc/Makefile
 567 doc/version.sgml
 568 test/Makefile
 569 fontconfig.spec
 570 fontconfig.pc
 571 fonts.conf
 572 fontconfig-zip
 573 ])