configure.in

   1 dnl
   2 dnl  $Id$
   3 dnl
   4 dnl  Copyright © 2003 Keith Packard
   5 dnl
   6 dnl  Permission to use, copy, modify, distribute, and sell this software and its
   7 dnl  documentation for any purpose is hereby granted without fee, provided that
   8 dnl  the above copyright notice appear in all copies and that both that
   9 dnl  copyright notice and this permission notice appear in supporting
  10 dnl  documentation, and that the name of Keith Packard not be used in
  11 dnl  advertising or publicity pertaining to distribution of the software without
  12 dnl  specific, written prior permission.  Keith Packard makes no
  13 dnl  representations about the suitability of this software for any purpose.  It
  14 dnl  is provided "as is" without express or implied warranty.
  15 dnl
  16 dnl  KEITH PACKARD DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
  17 dnl  INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
  18 dnl  EVENT SHALL KEITH PACKARD BE LIABLE FOR ANY SPECIAL, INDIRECT OR
  19 dnl  CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
  20 dnl  DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
  21 dnl  TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
  22 dnl  PERFORMANCE OF THIS SOFTWARE.
  23 dnl
  24 dnl Process this file with autoconf to create configure.
  25
  26 AC_INIT(fonts.dtd)
  27
  28 dnl ==========================================================================
  29 dnl                               Versioning
  30 dnl ==========================================================================
  31
  32 dnl This is the package version number, not the shared library
  33 dnl version.  This same version number must appear in fontconfig/fontconfig.h
  34 dnl Yes, it is a pain to synchronize version numbers.  Unfortunately, it's
  35 dnl not possible to extract the version number here from fontconfig.h
  36 AM_INIT_AUTOMAKE(fontconfig, 2.3.94)
  37 AM_MAINTAINER_MODE
  38
  39 dnl libtool versioning
  40
  41 LT_CURRENT=1
  42 LT_REVISION=4
  43 AC_SUBST(LT_CURRENT)
  44 AC_SUBST(LT_REVISION)
  45 LT_AGE=0
  46
  47 LT_VERSION_INFO="$LT_CURRENT:$LT_REVISION:$LT_AGE"
  48 AC_SUBST(LT_VERSION_INFO)
  49
  50 LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
  51 AC_SUBST(LT_CURRENT_MINUS_AGE)
  52
  53 dnl ==========================================================================
  54
  55 AM_CONFIG_HEADER(config.h)
  56
  57 AC_PROG_CC
  58 AC_PROG_INSTALL
  59 AC_PROG_LN_S
  60 AC_LIBTOOL_WIN32_DLL
  61 AM_PROG_LIBTOOL
  62 AC_PROG_MAKE_SET
  63
  64 dnl ==========================================================================
  65
  66 case "$host" in
  67   *-*-mingw*)
  68     os_win32=yes
  69     ;;
  70   *)
  71     os_win32=no
  72 esac
  73 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
  74
  75 if test "$os_win32" = "yes"; then
  76   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
  77 fi
  78 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
  79
  80 WARN_CFLAGS=""
  81
  82 if test "x$GCC" = "xyes"; then
  83         WARN_CFLAGS="-Wall -Wpointer-arith -Wstrict-prototypes \
  84         -Wmissing-prototypes -Wmissing-declarations \
  85         -Wnested-externs -fno-strict-aliasing"
  86 fi
  87 AC_SUBST(WARN_CFLAGS)
  88
  89 dnl ==========================================================================
  90
  91 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
  92
  93 dnl ==========================================================================
  94
  95 # Setup for compiling build tools (fc-glyphname, etc)
  96 AC_MSG_CHECKING([for a C compiler for build tools])
  97 if test $cross_compiling = yes; then
  98   AC_CHECK_PROGS(CC_FOR_BUILD, gcc cc)
  99 else
 100   CC_FOR_BUILD=$CC
 101 fi
 102 AC_MSG_RESULT([$CC_FOR_BUILD])
 103 AC_SUBST(CC_FOR_BUILD)
 104
 105 AC_MSG_CHECKING([for suffix of executable build tools])
 106 if test $cross_compiling = yes; then
 107   cat >conftest.c <<\_______EOF
 108 int
 109 main ()
 110 {
 111   exit (0);
 112 }
 113 _______EOF
 114   for i in .exe ""; do
 115     compile="$CC_FOR_BUILD conftest.c -o conftest$i"
 116     if AC_TRY_EVAL(compile); then
 117       if (./conftest) 2>&AC_FD_CC; then
 118         EXEEXT_FOR_BUILD=$i
 119         break
 120       fi
 121     fi
 122   done
 123   rm -f conftest*
 124   if test "${EXEEXT_FOR_BUILD+set}" != set; then
 125     AC_MSG_ERROR([Cannot determine suffix of executable build tools])
 126   fi
 127 else
 128   EXEEXT_FOR_BUILD=$EXEEXT
 129 fi
 130 AC_MSG_RESULT([$EXEEXT_FOR_BUILD])
 131 AC_SUBST(EXEEXT_FOR_BUILD)
 132
 133 dnl ==========================================================================
 134
 135 # Checks for header files.
 136 AC_HEADER_DIRENT
 137 AC_HEADER_STDC
 138 AC_CHECK_HEADERS([fcntl.h stdlib.h string.h unistd.h iconv.h])
 139
 140 # Checks for typedefs, structures, and compiler characteristics.
 141 AC_C_CONST
 142 AC_C_INLINE
 143 AC_TYPE_PID_T
 144
 145 # Checks for library functions.
 146 AC_FUNC_VPRINTF
 147 AC_FUNC_MMAP
 148 AC_CHECK_FUNCS([geteuid getuid link memmove memset mkstemp strchr strrchr strtol getopt getopt_long iconv sysconf ftruncate chsize rand_r])
 149
 150 #
 151 # Checks for FreeType
 152 #
 153
 154 AC_ARG_WITH(freetype-config, [  --with-freetype-config=PROG   Use FreeType configuration program PROG], freetype_config=$withval, freetype_config=yes)
 155
 156 if test "$freetype_config" = "yes"; then
 157         AC_PATH_PROG(ft_config,freetype-config,no)
 158         if test "$ft_config" = "no"; then
 159                 AC_MSG_ERROR([You must have freetype installed; see http://www.freetype.org/])
 160         fi
 161 else
 162         ft_config="$freetype_config"
 163 fi
 164
 165 FREETYPE_CFLAGS="`$ft_config --cflags`"
 166 FREETYPE_LIBS="`$ft_config --libs`"
 167
 168 AC_SUBST(FREETYPE_LIBS)
 169 AC_SUBST(FREETYPE_CFLAGS)
 170
 171 #
 172 # Check to see whether we have:
 173 #  FT_Get_Next_Char
 174 #  FT_Get_BDF_Property
 175 #  FT_Get_PS_Font_Info
 176 #  FT_Has_PS_Glyph_Names
 177 #
 178
 179 fontconfig_save_libs="$LIBS"
 180 fontconfig_save_cflags="$CFLAGS"
 181 LIBS="$LIBS $FREETYPE_LIBS"
 182 CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
 183 AC_CHECK_FUNCS(FT_Get_Next_Char FT_Get_BDF_Property FT_Get_PS_Font_Info FT_Has_PS_Glyph_Names FT_Get_X11_Font_Format)
 184 AC_CHECK_MEMBER(FT_Bitmap_Size.y_ppem,
 185                 HAVE_FT_BITMAP_SIZE_Y_PPEM=1,
 186                 HAVE_FT_BITMAP_SIZE_Y_PPEM=0,
 187 [#include <ft2build.h>
 188 #include FT_FREETYPE_H])
 189 AC_DEFINE_UNQUOTED(HAVE_FT_BITMAP_SIZE_Y_PPEM,$HAVE_FT_BITMAP_SIZE_Y_PPEM,
 190                    [FT_Bitmap_Size structure includes y_ppem field])
 191 CFLAGS="$fontconfig_save_cflags"
 192 LIBS="$fontconfig_save_libs"
 193
 194 #
 195 # Check expat configuration
 196 #
 197
 198 AC_ARG_WITH(expat,             [  --with-expat=DIR              Use Expat in DIR], expat=$withval, expat=yes)
 199 AC_ARG_WITH(expat-includes,    [  --with-expat-includes=DIR     Use Expat includes in DIR], expat_includes=$withval, expat_includes=yes)
 200 AC_ARG_WITH(expat-lib,         [  --with-expat-lib=DIR          Use Expat library in DIR], expat_lib=$withval, expat_lib=yes)
 201
 202 if test "$enable_libxml2" != "yes"; then
 203         case "$expat" in
 204         no)
 205         ;;
 206         *)
 207                 case "$expat_includes" in
 208                 yes)
 209                         case "$expat" in
 210                         yes)
 211                                 ;;
 212                         *)
 213                                 EXPAT_CFLAGS="-I$expat/include"
 214                                 ;;
 215                         esac
 216                         ;;
 217                 no)
 218                         EXPAT_CFLAGS=""
 219                         ;;
 220                 *)
 221                         EXPAT_CFLAGS="-I$expat_includes"
 222                         ;;
 223                 esac
 224                 case "$expat_lib" in
 225                 yes)
 226                         case "$expat" in
 227                         yes)
 228                                 EXPAT_LIBS="-lexpat"
 229                                 ;;
 230                         *)
 231                                 EXPAT_LIBS="-L$expat/lib -lexpat"
 232                                 ;;
 233                         esac
 234                         ;;
 235                 no)
 236                         ;;
 237                 *)
 238                         EXPAT_LIBS="-L$expat_lib -lexpat"
 239                         ;;
 240                 esac
 241
 242                 expatsaved_CPPFLAGS="$CPPFLAGS"
 243                 CPPFLAGS="$CPPFLAGS $EXPAT_CFLAGS"
 244                 expatsaved_LIBS="$LIBS"
 245                 LIBS="$LIBS $EXPAT_LIBS"
 246
 247                 AC_CHECK_HEADER(expat.h)
 248                 case "$ac_cv_header_expat_h" in
 249                 no)
 250                         AC_CHECK_HEADER(xmlparse.h)
 251                         case "$ac_cv_header_xmlparse_h" in
 252                         no)
 253                                 have_expat_header=no;
 254                                 ;;
 255                         yes)
 256                                 HAVE_XMLPARSE_H=1
 257                                 AC_SUBST(HAVE_XMLPARSE_H)
 258                                 AC_DEFINE_UNQUOTED(HAVE_XMLPARSE_H,$HAVE_XMLPARSE_H,
 259                                 [Use xmlparse.h instead of expat.h])
 260                                 have_expat_header=yes
 261                                 ;;
 262                         esac
 263                         ;;
 264                 yes)
 265                         have_expat_header=yes
 266                         ;;
 267                 esac
 268                 case "$have_expat_header" in
 269                 no)
 270                         expat=no
 271                         ;;
 272                 yes)
 273                         AC_CHECK_FUNCS(XML_SetDoctypeDeclHandler)
 274                         case "$ac_cv_func_XML_SetDoctypeDeclHandler" in
 275                         yes)
 276                                 HAVE_EXPAT=1
 277                                 AC_SUBST(HAVE_EXPAT)
 278                                 AC_DEFINE_UNQUOTED(HAVE_EXPAT,$HAVE_EXPAT,
 279                                 [Found a useable expat library])
 280                                 ;;
 281                         *)
 282                                 expat=no
 283                                 ;;
 284                         esac
 285                         ;;
 286                 esac
 287                 CPPFLAGS="$expatsaved_CPPFLAGS"
 288                 LIBS="$expatsaved_LIBS"
 289                 ;;
 290         esac
 291
 292         AC_SUBST(EXPAT_CFLAGS)
 293         AC_SUBST(EXPAT_LIBS)
 294
 295         case "$expat" in
 296         no)
 297                 EXPAT_CFLAGS=""
 298                 EXPAT_LIBS=""
 299
 300                 AC_MSG_WARN([Cannot find usable expat library. Trying to use libxml2 as fallback.])
 301                 ;;
 302         esac
 303 fi
 304
 305 #
 306 # Check libxml2 configuration
 307 #
 308
 309 AC_ARG_ENABLE(libxml2,         [  --enable-libxml2              Use libxml2 instead of Expat])
 310
 311 PKG_PROG_PKG_CONFIG
 312
 313 if test "$enable_libxml2" = "yes" -o "$expat" = "no"; then
 314     PKG_CHECK_MODULES([LIBXML2], [libxml-2.0 >= 2.6])
 315     AC_DEFINE_UNQUOTED(ENABLE_LIBXML2,1,[Use libxml2 instead of Expat])
 316
 317     AC_SUBST(LIBXML2_CFLAGS)
 318     AC_SUBST(LIBXML2_LIBS)
 319 fi
 320
 321 #
 322 # Set default font directory
 323 #
 324
 325 AC_ARG_WITH(default-fonts,     [  --with-default-fonts=DIR      Use fonts from DIR when config is busted], default_fonts="$withval", default_fonts=yes)
 326
 327 case "$default_fonts" in
 328 yes)
 329         if test "$os_win32" = "yes"; then
 330                 FC_DEFAULT_FONTS="WINDOWSFONTDIR"
 331                 AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "WINDOWSFONTDIR",
 332                                    [Windows font directory])
 333         else
 334                 FC_DEFAULT_FONTS="/usr/share/fonts"
 335                 AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "/usr/share/fonts",
 336                                    [System font directory])
 337         fi
 338         ;;
 339 *)
 340         FC_DEFAULT_FONTS="$default_fonts"
 341         AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "$default_fonts",
 342                            [System font directory])
 343         ;;
 344 esac
 345
 346 AC_SUBST(FC_DEFAULT_FONTS)
 347
 348 #
 349 # Add more fonts if available.  By default, add only the directories
 350 # with outline fonts; those with bitmaps can be added as desired in
 351 # local.conf or ~/.fonts.conf
 352 #
 353 AC_ARG_WITH(add-fonts,        [  --with-add-fonts=DIR1,DIR2,...Find additional fonts in DIR1,DIR2,... ], add_fonts="$withval", add_fonts=yes)
 354
 355 case "$add_fonts" in
 356 yes)
 357         FC_ADD_FONTS=""
 358         for dir in /usr/X11R6/lib/X11 /usr/X11/lib/X11 /usr/lib/X11; do
 359                 case x"$FC_ADD_FONTS" in
 360                 x)
 361                         sub="$dir/fonts"
 362                         if test -d "$sub"; then
 363                                 case x$FC_ADD_FONTS in
 364                                 x)
 365                                         FC_ADD_FONTS="$sub"
 366                                         ;;
 367                                 *)
 368                                         FC_ADD_FONTS="$FC_ADD_FONTS,$sub"
 369                                         ;;
 370                                 esac
 371                         fi
 372                         ;;
 373                 esac
 374         done
 375         AC_DEFINE_UNQUOTED(FC_ADD_FONTS,"$add_fonts",[Additional font directories])
 376         ;;
 377 no)
 378         FC_ADD_FONTS=""
 379         ;;
 380 *)
 381         FC_ADD_FONTS="$add_fonts"
 382         AC_DEFINE_UNQUOTED(FC_ADD_FONTS,"$add_fonts",[Additional font directories])
 383         ;;
 384 esac
 385
 386 AC_SUBST(FC_ADD_FONTS)
 387
 388 FC_FONTPATH=""
 389
 390 case "$FC_ADD_FONTS" in
 391 "")
 392         ;;
 393 *)
 394         FC_FONTPATH=`echo $FC_ADD_FONTS |
 395                         sed -e 's/^/<dir>/' -e 's/$/<\/dir>/' -e 's/,/<\/dir> <dir>/g'`
 396         ;;
 397 esac
 398
 399 AC_SUBST(FC_FONTPATH)
 400
 401 FC_FONTDATE=`LC_ALL=C date`
 402
 403 AC_SUBST(FC_FONTDATE)
 404
 405 AC_ARG_WITH(confdir,           [  --with-confdir=DIR            Use DIR to store configuration files (default /etc/fonts)], confdir="$withval", confdir=yes)
 406
 407 #
 408 # Set CONFDIR and FONTCONFIG_PATH
 409 #
 410
 411 case "$confdir" in
 412 no|yes)
 413         confdir='${sysconfdir}'/fonts
 414         ;;
 415 *)
 416         ;;
 417 esac
 418 AC_SUBST(confdir)
 419 CONFDIR=${confdir}
 420 AC_DEFINE_UNQUOTED(CONFDIR, "$CONFDIR",[Font configuration directory])
 421 AC_SUBST(CONFDIR)
 422
 423 #
 424 # Find out what language orthographies are included
 425 #
 426
 427 ORTH_FILES=`cd ${srcdir}/fc-lang && echo *.orth`
 428 AC_SUBST(ORTH_FILES)
 429
 430 #
 431 # Let people not build/install docs if they don't have docbook
 432 #
 433
 434 AC_CHECK_PROG(HASDOCBOOK, docbook2html, yes, no)
 435
 436 AM_CONDITIONAL(USEDOCBOOK, test "x$HASDOCBOOK" = xyes)
 437
 438 default_docs="yes"
 439 #
 440 # Check if docs exist or can be created
 441 #
 442 if test x$HASDOCBOOK = xno; then
 443         if test -f doc/fonts-conf.5; then
 444                 :
 445         else
 446                 default_docs="no"
 447         fi
 448 fi
 449
 450 AC_ARG_ENABLE(docs,           [  --disable-docs                Don't build and install documentation],,enable_docs=$default_docs)
 451
 452 AM_CONDITIONAL(ENABLE_DOCS, test "x$enable_docs" = xyes)
 453
 454 if test "x$enable_docs" = xyes; then
 455         DOCSRC="doc"
 456         tmp=funcs.$$
 457         cat $srcdir/doc/*.fncs | awk '
 458         /^@TITLE@/      { if (!done) { printf ("%s\n", $2); done = 1; } }
 459         /^@FUNC@/       { if (!done) { printf ("%s\n", $2); done = 1; } }
 460         /^@@/           { done = 0; }' > $tmp
 461         DOCMAN3=`cat $tmp | awk '{ printf ("%s.3 ", $1); }'`
 462         echo DOCMAN3 $DOCMAN3
 463         rm -f $tmp
 464 else
 465         DOCSRC=""
 466         DOCMAN3=""
 467 fi
 468
 469 AC_SUBST(DOCSRC)
 470 AC_SUBST(DOCMAN3)
 471
 472 #
 473 # Figure out where to install documentation
 474 #
 475
 476 AC_ARG_WITH(docdir,           [  --with-docdir=DIR             Use DIR to store documentation files (default ${datadir}/doc/fontconfig)], confdir="$withval")
 477
 478 if test "x$with_docdir" = "x" ; then
 479   DOCDIR='${datadir}/doc/fontconfig'
 480 else
 481   DOCDIR=$with_docdir
 482 fi
 483
 484 AC_SUBST(DOCDIR)
 485
 486 #
 487 # Make /var/cache/fontconfig directory available to source code
 488 #
 489
 490 pkgcachedir='${localstatedir}/cache/'${PACKAGE}
 491 AC_SUBST(pkgcachedir)
 492
 493 AC_OUTPUT([
 494 Makefile
 495 fontconfig/Makefile
 496 fc-lang/Makefile
 497 fc-glyphname/Makefile
 498 fc-case/Makefile
 499 src/Makefile
 500 src/fontconfig.def
 501 conf.d/Makefile
 502 fc-cache/Makefile
 503 fc-cat/Makefile
 504 fc-list/Makefile
 505 fc-match/Makefile
 506 doc/Makefile
 507 doc/version.sgml
 508 test/Makefile
 509 fontconfig.spec
 510 fontconfig.pc
 511 fonts.conf
 512 fontconfig-zip
 513 ])