configure.in

   1 dnl
   2 dnl  $Id$
   3 dnl
   4 dnl  Copyright © 2003 Keith Packard
   5 dnl
   6 dnl  Permission to use, copy, modify, distribute, and sell this software and its
   7 dnl  documentation for any purpose is hereby granted without fee, provided that
   8 dnl  the above copyright notice appear in all copies and that both that
   9 dnl  copyright notice and this permission notice appear in supporting
  10 dnl  documentation, and that the name of Keith Packard not be used in
  11 dnl  advertising or publicity pertaining to distribution of the software without
  12 dnl  specific, written prior permission.  Keith Packard makes no
  13 dnl  representations about the suitability of this software for any purpose.  It
  14 dnl  is provided "as is" without express or implied warranty.
  15 dnl
  16 dnl  KEITH PACKARD DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
  17 dnl  INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
  18 dnl  EVENT SHALL KEITH PACKARD BE LIABLE FOR ANY SPECIAL, INDIRECT OR
  19 dnl  CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
  20 dnl  DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
  21 dnl  TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
  22 dnl  PERFORMANCE OF THIS SOFTWARE.
  23 dnl
  24 dnl Process this file with autoconf to create configure.
  25
  26 AC_INIT(fonts.dtd)
  27
  28 dnl ==========================================================================
  29 dnl                               Versioning
  30 dnl ==========================================================================
  31
  32 dnl This is the package version number, not the shared library
  33 dnl version.  This same version number must appear in fontconfig/fontconfig.h
  34 dnl Yes, it is a pain to synchronize version numbers.  Unfortunately, it's
  35 dnl not possible to extract the version number here from fontconfig.h
  36 AM_INIT_AUTOMAKE(fontconfig, 2.2.92)
  37
  38 dnl libtool versioning
  39
  40 LT_CURRENT=1
  41 LT_REVISION=4
  42 AC_SUBST(LT_CURRENT)
  43 AC_SUBST(LT_REVISION)
  44 LT_AGE=0
  45
  46 LT_VERSION_INFO="$LT_CURRENT:$LT_REVISION:$LT_AGE"
  47 AC_SUBST(LT_VERSION_INFO)
  48
  49 LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
  50 AC_SUBST(LT_CURRENT_MINUS_AGE)
  51
  52 dnl ==========================================================================
  53
  54 AM_CONFIG_HEADER(config.h)
  55
  56 AC_PROG_CC
  57 AC_PROG_INSTALL
  58 AC_PROG_LN_S
  59 AC_LIBTOOL_WIN32_DLL
  60 AM_PROG_LIBTOOL
  61 AC_PROG_MAKE_SET
  62
  63 dnl ==========================================================================
  64
  65 case "$host" in
  66   *-*-mingw*)
  67     os_win32=yes
  68     ;;
  69   *)
  70     os_win32=no
  71 esac
  72 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
  73
  74 if test "$os_win32" = "yes"; then
  75   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
  76 fi
  77 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
  78
  79 dnl ==========================================================================
  80
  81 # Checks for header files.
  82 AC_HEADER_DIRENT
  83 AC_HEADER_STDC
  84 AC_CHECK_HEADERS([fcntl.h stdlib.h string.h unistd.h])
  85
  86 # Checks for typedefs, structures, and compiler characteristics.
  87 AC_C_CONST
  88 AC_TYPE_PID_T
  89
  90 # Checks for library functions.
  91 AC_FUNC_VPRINTF
  92 AC_CHECK_FUNCS([geteuid getuid link memmove memset mkstemp strchr strrchr strtol getopt getopt_long])
  93
  94 #
  95 # Checks for FreeType
  96 #
  97
  98 AC_ARG_WITH(freetype-config, [  --with-freetype-config=PROG   Use FreeType configuration program PROG], freetype_config=$withval, freetype_config=yes)
  99
 100 if test "$freetype_config" = "yes"; then
 101         AC_PATH_PROG(ft_config,freetype-config,no)
 102         if test "$ft_config" = "no"; then
 103                 AC_MSG_ERROR([You must have freetype installed; see http://www.freetype.org/])
 104         fi
 105 else
 106         ft_config="$freetype_config"
 107 fi
 108
 109 FREETYPE_CFLAGS="`$ft_config --cflags`"
 110 FREETYPE_LIBS="`$ft_config --libs`"
 111
 112 AC_SUBST(FREETYPE_LIBS)
 113 AC_SUBST(FREETYPE_CFLAGS)
 114
 115 #
 116 # Check to see whether we have:
 117 #  FT_Get_Next_Char
 118 #  FT_Get_BDF_Property
 119 #  FT_Get_PS_Font_Info
 120 #  FT_Has_PS_Glyph_Names
 121 #
 122
 123 fontconfig_save_libs="$LIBS"
 124 fontconfig_save_cflags="$CFLAGS"
 125 LIBS="$LIBS $FREETYPE_LIBS"
 126 CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
 127 AC_CHECK_FUNCS(FT_Get_Next_Char FT_Get_BDF_Property FT_Get_PS_Font_Info FT_Has_PS_Glyph_Names)
 128 AC_CHECK_MEMBER(FT_Bitmap_Size.y_ppem,,,
 129 [#include <ft2build.h>
 130 #include FT_FREETYPE_H])
 131 LIBS="$fontconfig_save_libs"
 132 CFLAGS="$fontconfig_save_cflags"
 133
 134 case "$ac_cv_member_FT_Bitmap_Size_y_ppem" in
 135 yes)
 136         HAVE_FT_BITMAP_SIZE_Y_PPEM=1
 137         ;;
 138 *)
 139         HAVE_FT_BITMAP_SIZE_Y_PPEM=0
 140         ;;
 141 esac
 142 AC_DEFINE_UNQUOTED(HAVE_FT_BITMAP_SIZE_Y_PPEM,$HAVE_FT_BITMAP_SIZE_Y_PPEM,
 143                    [FT_Bitmap_Size structure includes y_ppem field])
 144
 145 #
 146 # Check expat configuration
 147 #
 148
 149 AC_ARG_WITH(expat,             [  --with-expat=DIR              Use Expat in DIR], expat=$withval, expat=yes)
 150 AC_ARG_WITH(expat-includes,    [  --with-expat-includes=DIR     Use Expat includes in DIR], expat_includes=$withval, expat_includes=yes)
 151 AC_ARG_WITH(expat-lib,         [  --with-expat-lib=DIR          Use Expat library in DIR], expat_lib=$withval, expat_lib=yes)
 152
 153 case "$expat" in
 154 no)
 155         ;;
 156 *)
 157         case "$expat_includes" in
 158         yes|no)
 159                 EXPAT_CFLAGS=""
 160                 ;;
 161         *)
 162                 EXPAT_CFLAGS="-I$expat_includes"
 163                 ;;
 164         esac
 165         case "$expat_lib" in
 166         yes)
 167                 case "$expat" in
 168                 yes)
 169                         EXPAT_LIBS="-lexpat"
 170                         ;;
 171                 *)
 172                         EXPAT_LIBS="-L$expat/lib -lexpat"
 173                         ;;
 174                 esac
 175                 ;;
 176         no)
 177                 ;;
 178         *)
 179                 EXPAT_LIBS="-L$expat_lib -lexpat"
 180                 ;;
 181         esac
 182
 183         expatsaved_CPPFLAGS="$CPPFLAGS"
 184         CPPFLAGS="$CPPFLAGS $EXPAT_CFLAGS"
 185         expatsaved_LIBS="$LIBS"
 186         LIBS="$LIBS $EXPAT_LIBS"
 187
 188         AC_CHECK_HEADER(expat.h)
 189         case "$ac_cv_header_expat_h" in
 190         no)
 191                 AC_CHECK_HEADER(xmlparse.h)
 192                 case "$ac_cv_header_xmlparse_h" in
 193                 no)
 194                         have_expat_header=no;
 195                         ;;
 196                 yes)
 197                         HAVE_XMLPARSE_H=1
 198                         AC_SUBST(HAVE_XMLPARSE_H)
 199                         AC_DEFINE_UNQUOTED(HAVE_XMLPARSE_H,$HAVE_XMLPARSE_H,
 200                         [Use xmlparse.h instead of expat.h])
 201                         have_expat_header=yes
 202                         ;;
 203                 esac
 204                 ;;
 205         yes)
 206                 have_expat_header=yes
 207                 ;;
 208         esac
 209         case "$have_expat_header" in
 210         no)
 211                 expat=no
 212                 ;;
 213         yes)
 214                 AC_CHECK_FUNCS(XML_SetDoctypeDeclHandler)
 215                 case "$ac_cv_func_XML_SetDoctypeDeclHandler" in
 216                 yes)
 217                         HAVE_EXPAT=1
 218                         AC_SUBST(HAVE_EXPAT)
 219                         AC_DEFINE_UNQUOTED(HAVE_EXPAT,$HAVE_EXPAT,
 220                         [Found a useable expat library])
 221                         ;;
 222                 *)
 223                         expat=no
 224                         ;;
 225                 esac
 226                 ;;
 227         esac
 228         CPPFLAGS="$expatsaved_CPPFLAGS"
 229         LIBS="$expatsaved_LIBS"
 230         ;;
 231 esac
 232 AC_SUBST(EXPAT_LIBS)
 233 AC_SUBST(EXPAT_CFLAGS)
 234
 235 case "$expat" in
 236 no)
 237         AC_MSG_ERROR([Cannot find usable expat library. This could mean that your version is too old.])
 238         ;;
 239 esac
 240
 241 #
 242 # Set default font directory
 243 #
 244
 245 AC_ARG_WITH(default-fonts,     [  --with-default-fonts=DIR      Use fonts from DIR when config is busted], default_fonts="$withval", default_fonts=yes)
 246
 247 case "$default_fonts" in
 248 yes)
 249         if test "$os_win32" = "yes"; then
 250                 FC_DEFAULT_FONTS="WINDOWSFONTDIR"
 251                 AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "WINDOWSFONTDIR",
 252                                    [Windows font directory])
 253         else
 254                 FC_DEFAULT_FONTS="/usr/share/fonts"
 255                 AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "/usr/share/fonts",
 256                                    [System font directory])
 257         fi
 258         ;;
 259 *)
 260         FC_DEFAULT_FONTS="$default_fonts"
 261         AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "$default_fonts",
 262                            [System font directory])
 263         ;;
 264 esac
 265
 266 AC_SUBST(FC_DEFAULT_FONTS)
 267
 268 #
 269 # Add more fonts if available.  By default, add only the directories
 270 # with outline fonts; those with bitmaps can be added as desired in
 271 # local.conf or ~/.fonts.conf
 272 #
 273 AC_ARG_WITH(add-fonts,        [  --with-add-fonts=DIR1,DIR2,...Find additional fonts in DIR1,DIR2,... ], add_fonts="$withval", add_fonts=yes)
 274
 275 case "$add_fonts" in
 276 yes)
 277         FC_ADD_FONTS=""
 278         for dir in /usr/X11R6/lib/X11 /usr/X11/lib/X11 /usr/lib/X11; do
 279                 case x"$FC_ADD_FONTS" in
 280                 x)
 281                         if test -d "$dir/fonts"; then
 282                                 for sub in "$dir"/fonts/*; do
 283                                         if ls "$sub" | grep -q -i '\.pf\|\.tt\|\.ot'; then
 284                                                 case x$FC_ADD_FONTS in
 285                                                 x)
 286                                                         FC_ADD_FONTS="$sub"
 287                                                         ;;
 288                                                 *)
 289                                                         FC_ADD_FONTS="$FC_ADD_FONTS,$sub"
 290                                                         ;;
 291                                                 esac
 292                                         fi
 293                                 done
 294                         fi
 295                         ;;
 296                 esac
 297         done
 298         AC_DEFINE_UNQUOTED(FC_ADD_FONTS,"$add_fonts",[Additional font directories])
 299         ;;
 300 no)
 301         FC_ADD_FONTS=""
 302         ;;
 303 *)
 304         FC_ADD_FONTS="$add_fonts"
 305         AC_DEFINE_UNQUOTED(FC_ADD_FONTS,"$add_fonts",[Additional font directories])
 306         ;;
 307 esac
 308
 309 AC_SUBST(FC_ADD_FONTS)
 310
 311 FC_FONTPATH=""
 312
 313 case "$FC_ADD_FONTS" in
 314 "")
 315         ;;
 316 *)
 317         FC_FONTPATH=`echo $FC_ADD_FONTS |
 318                         sed -e 's/^/<dir>/' -e 's/$/<\/dir>/' -e 's/,/<\/dir> <dir>/g'`
 319         ;;
 320 esac
 321
 322 AC_SUBST(FC_FONTPATH)
 323
 324 FC_FONTDATE=`date`
 325
 326 AC_SUBST(FC_FONTDATE)
 327
 328 AC_ARG_WITH(confdir,           [  --with-confdir=DIR            Use DIR to store configuration files (default /etc/fonts)], confdir="$withval", confdir=yes)
 329
 330 #
 331 # Set CONFDIR and FONTCONFIG_PATH
 332 #
 333
 334 case "$confdir" in
 335 no|yes)
 336         confdir='${sysconfdir}'/fonts
 337         ;;
 338 *)
 339         ;;
 340 esac
 341 AC_SUBST(confdir)
 342 CONFDIR=${confdir}
 343 AC_DEFINE_UNQUOTED(CONFDIR, "$CONFDIR",[Font configuration directory])
 344 AC_SUBST(CONFDIR)
 345
 346 #
 347 # Find out what language orthographies are included
 348 #
 349
 350 ORTH_FILES=`cd ${srcdir}/fc-lang && echo *.orth`
 351 AC_SUBST(ORTH_FILES)
 352
 353 #
 354 # Let people not build/install docs if they don't have docbook
 355 #
 356
 357 AC_CHECK_PROG(HASDOCBOOK, docbook2html, yes, no)
 358
 359 AM_CONDITIONAL(USEDOCBOOK, test "x$HASDOCBOOK" = xyes)
 360
 361 default_docs="yes"
 362 #
 363 # Check if docs exist or can be created
 364 #
 365 if test x$HASDOCBOOK = xno; then
 366         if test -f doc/fonts-conf.5; then
 367                 :
 368         else
 369                 default_docs="no"
 370         fi
 371 fi
 372
 373 AC_ARG_ENABLE(docs,           [  --disable-docs                Don't build and install documentation],,enable_docs=$default_docs)
 374
 375 AM_CONDITIONAL(ENABLE_DOCS, test "x$enable_docs" = xyes)
 376
 377 if test "x$enable_docs" = xyes; then
 378         DOCSRC="doc"
 379         tmp=funcs.$$
 380         cat $srcdir/doc/*.fncs | awk '
 381         /^@TITLE@/      { if (!done) { printf ("%s\n", $2); done = 1; } }
 382         /^@FUNC@/       { if (!done) { printf ("%s\n", $2); done = 1; } }
 383         /^@@/           { done = 0; }' > $tmp
 384         DOCMAN3=`cat $tmp | awk '{ printf ("%s.3 ", $1); }'`
 385         echo DOCMAN3 $DOCMAN3
 386         rm -f $tmp
 387 else
 388         DOCSRC=""
 389         DOCMAN3=""
 390 fi
 391
 392 AC_SUBST(DOCSRC)
 393 AC_SUBST(DOCMAN3)
 394
 395 #
 396 # Figure out where to install documentation
 397 #
 398
 399 AC_ARG_WITH(docdir,           [  --with-docdir=DIR             Use DIR to store documentation files (default ${datadir}/doc/fontconfig)], confdir="$withval")
 400
 401 if test "x$with_docdir" = "x" ; then
 402   DOCDIR='${datadir}/doc/fontconfig'
 403 else
 404   DOCDIR=$with_docdir
 405 fi
 406
 407 AC_SUBST(DOCDIR)
 408
 409 AC_OUTPUT([
 410 Makefile
 411 fontconfig/Makefile
 412 fc-lang/Makefile
 413 fc-glyphname/Makefile
 414 src/Makefile
 415 src/fontconfig.def
 416 fc-cache/Makefile
 417 fc-list/Makefile
 418 fc-match/Makefile
 419 doc/Makefile
 420 doc/version.sgml
 421 test/Makefile
 422 fontconfig.spec
 423 fontconfig.pc
 424 fonts.conf
 425 fontconfig-zip
 426 ])