configure.in

   1 dnl
   2 dnl  $Id$
   3 dnl
   4 dnl  Copyright © 2003 Keith Packard
   5 dnl
   6 dnl  Permission to use, copy, modify, distribute, and sell this software and its
   7 dnl  documentation for any purpose is hereby granted without fee, provided that
   8 dnl  the above copyright notice appear in all copies and that both that
   9 dnl  copyright notice and this permission notice appear in supporting
  10 dnl  documentation, and that the name of Keith Packard not be used in
  11 dnl  advertising or publicity pertaining to distribution of the software without
  12 dnl  specific, written prior permission.  Keith Packard makes no
  13 dnl  representations about the suitability of this software for any purpose.  It
  14 dnl  is provided "as is" without express or implied warranty.
  15 dnl
  16 dnl  KEITH PACKARD DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
  17 dnl  INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
  18 dnl  EVENT SHALL KEITH PACKARD BE LIABLE FOR ANY SPECIAL, INDIRECT OR
  19 dnl  CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
  20 dnl  DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
  21 dnl  TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
  22 dnl  PERFORMANCE OF THIS SOFTWARE.
  23 dnl
  24 dnl Process this file with autoconf to create configure.
  25
  26 AC_INIT(fonts.dtd)
  27
  28 dnl ==========================================================================
  29 dnl                               Versioning
  30 dnl ==========================================================================
  31
  32 dnl This is the package version number, not the shared library
  33 dnl version.  This same version number must appear in fontconfig/fontconfig.h
  34 dnl Yes, it is a pain to synchronize version numbers.  Unfortunately, it's
  35 dnl not possible to extract the version number here from fontconfig.h
  36 AM_INIT_AUTOMAKE(fontconfig, 2.2.90)
  37
  38 dnl libtool versioning
  39
  40 LT_CURRENT=1
  41 LT_REVISION=4
  42 AC_SUBST(LT_CURRENT)
  43 AC_SUBST(LT_REVISION)
  44 LT_AGE=0
  45
  46 LT_VERSION_INFO="$LT_CURRENT:$LT_REVISION:$LT_AGE"
  47 AC_SUBST(LT_VERSION_INFO)
  48
  49 LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
  50 AC_SUBST(LT_CURRENT_MINUS_AGE)
  51
  52 dnl ==========================================================================
  53
  54 AM_CONFIG_HEADER(config.h)
  55
  56 AC_PROG_CC
  57 AC_PROG_INSTALL
  58 AC_PROG_LN_S
  59 AC_LIBTOOL_WIN32_DLL
  60 AM_PROG_LIBTOOL
  61 AC_PROG_MAKE_SET
  62
  63 dnl ==========================================================================
  64
  65 case "$host" in
  66   *-*-mingw*)
  67     os_win32=yes
  68     ;;
  69   *)
  70     os_win32=no
  71 esac
  72 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
  73
  74 if test "$os_win32" = "yes"; then
  75   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
  76 fi
  77 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
  78
  79 dnl ==========================================================================
  80
  81 # Checks for header files.
  82 AC_HEADER_DIRENT
  83 AC_HEADER_STDC
  84 AC_CHECK_HEADERS([fcntl.h stdlib.h string.h unistd.h])
  85
  86 # Checks for typedefs, structures, and compiler characteristics.
  87 AC_C_CONST
  88 AC_TYPE_PID_T
  89
  90 # Checks for library functions.
  91 AC_FUNC_VPRINTF
  92 AC_CHECK_FUNCS([geteuid getuid link memmove memset mkstemp strchr strrchr strtol getopt getopt_long])
  93
  94 #
  95 # Checks for FreeType
  96 #
  97
  98 AC_ARG_WITH(freetype-config, [  --with-freetype-config=PROG   Use FreeType configuration program PROG], freetype_config=$withval, freetype_config=yes)
  99
 100 if test "$freetype_config" = "yes"; then
 101         AC_PATH_PROG(ft_config,freetype-config,no)
 102         if test "$ft_config" = "no"; then
 103                 AC_MSG_ERROR([You must have freetype installed; see http://www.freetype.org/])
 104         fi
 105 else
 106         ft_config="$freetype_config"
 107 fi
 108
 109 FREETYPE_CFLAGS="`$ft_config --cflags`"
 110 FREETYPE_LIBS="`$ft_config --libs`"
 111
 112 AC_SUBST(FREETYPE_LIBS)
 113 AC_SUBST(FREETYPE_CFLAGS)
 114
 115 #
 116 # Check to see whether we have:
 117 #  FT_Get_Next_Char
 118 #  FT_Get_BDF_Property
 119 #  FT_Get_PS_Font_Info
 120 #
 121
 122 fontconfig_save_libs=$LIBS
 123 LIBS="$LIBS $FREETYPE_LIBS"
 124 AC_CHECK_FUNCS(FT_Get_Next_Char FT_Get_BDF_Property FT_Get_PS_Font_Info)
 125 LIBS=$fontconfig_save_libs
 126
 127 #
 128 # Check expat configuration
 129 #
 130
 131 AC_ARG_WITH(expat,             [  --with-expat=DIR              Use Expat in DIR], expat=$withval, expat=yes)
 132 AC_ARG_WITH(expat-includes,    [  --with-expat-includes=DIR     Use Expat includes in DIR], expat_includes=$withval, expat_includes=yes)
 133 AC_ARG_WITH(expat-lib,         [  --with-expat-lib=DIR          Use Expat library in DIR], expat_lib=$withval, expat_lib=yes)
 134
 135 case "$expat" in
 136 no)
 137         ;;
 138 *)
 139         case "$expat_includes" in
 140         yes|no)
 141                 EXPAT_CFLAGS=""
 142                 ;;
 143         *)
 144                 EXPAT_CFLAGS="-I$expat_includes"
 145                 ;;
 146         esac
 147         case "$expat_lib" in
 148         yes)
 149                 case "$expat" in
 150                 yes)
 151                         EXPAT_LIBS="-lexpat"
 152                         ;;
 153                 *)
 154                         EXPAT_LIBS="-L$expat/lib -lexpat"
 155                         ;;
 156                 esac
 157                 ;;
 158         no)
 159                 ;;
 160         *)
 161                 EXPAT_LIBS="-L$expat_lib -lexpat"
 162                 ;;
 163         esac
 164
 165         expatsaved_CPPFLAGS="$CPPFLAGS"
 166         CPPFLAGS="$CPPFLAGS $EXPAT_CFLAGS"
 167         expatsaved_LIBS="$LIBS"
 168         LIBS="$LIBS $EXPAT_LIBS"
 169
 170         AC_CHECK_HEADER(expat.h)
 171         case "$ac_cv_header_expat_h" in
 172         no)
 173                 AC_CHECK_HEADER(xmlparse.h)
 174                 case "$ac_cv_header_xmlparse_h" in
 175                 no)
 176                         have_expat_header=no;
 177                         ;;
 178                 yes)
 179                         HAVE_XMLPARSE_H=1
 180                         AC_SUBST(HAVE_XMLPARSE_H)
 181                         AC_DEFINE_UNQUOTED(HAVE_XMLPARSE_H,$HAVE_XMLPARSE_H,
 182                         [Use xmlparse.h instead of expat.h])
 183                         have_expat_header=yes
 184                         ;;
 185                 esac
 186                 ;;
 187         yes)
 188                 have_expat_header=yes
 189                 ;;
 190         esac
 191         case "$have_expat_header" in
 192         no)
 193                 expat=no
 194                 ;;
 195         yes)
 196                 AC_CHECK_FUNCS(XML_SetDoctypeDeclHandler)
 197                 case "$ac_cv_func_XML_SetDoctypeDeclHandler" in
 198                 yes)
 199                         HAVE_EXPAT=1
 200                         AC_SUBST(HAVE_EXPAT)
 201                         AC_DEFINE_UNQUOTED(HAVE_EXPAT,$HAVE_EXPAT,
 202                         [Found a useable expat library])
 203                         ;;
 204                 *)
 205                         expat=no
 206                         ;;
 207                 esac
 208                 ;;
 209         esac
 210         CPPFLAGS="$expatsaved_CPPFLAGS"
 211         LIBS="$expatsaved_LIBS"
 212         ;;
 213 esac
 214 AC_SUBST(EXPAT_LIBS)
 215 AC_SUBST(EXPAT_CFLAGS)
 216
 217 case "$expat" in
 218 no)
 219         AC_MSG_ERROR([Cannot find usable expat library. This could mean that your version is too old.])
 220         ;;
 221 esac
 222
 223 #
 224 # Set default font directory
 225 #
 226
 227 AC_ARG_WITH(default-fonts,     [  --with-default-fonts=DIR      Use fonts from DIR when config is busted], default_fonts="$withval", default_fonts=yes)
 228
 229 case "$default_fonts" in
 230 yes)
 231         if test "$os_win32" = "yes"; then
 232                 FC_DEFAULT_FONTS="WINDOWSFONTDIR"
 233                 AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "WINDOWSFONTDIR",
 234                                    [Windows font directory])
 235         else
 236                 FC_DEFAULT_FONTS="/usr/share/fonts"
 237                 AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "/usr/share/fonts",
 238                                    [System font directory])
 239         fi
 240         ;;
 241 *)
 242         FC_DEFAULT_FONTS="$default_fonts"
 243         AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "$default_fonts",
 244                            [System font directory])
 245         ;;
 246 esac
 247
 248 AC_SUBST(FC_DEFAULT_FONTS)
 249
 250 #
 251 # Add more fonts if available.  By default, add only the directories
 252 # with outline fonts; those with bitmaps can be added as desired in
 253 # local.conf or ~/.fonts.conf
 254 #
 255 AC_ARG_WITH(add-fonts,        [  --with-add-fonts=DIR1,DIR2,...Find additional fonts in DIR1,DIR2,... ], add_fonts="$withval", add_fonts=yes)
 256
 257 case "$add_fonts" in
 258 yes)
 259         FC_ADD_FONTS=""
 260         for dir in /usr/X11R6/lib/X11 /usr/X11/lib/X11 /usr/lib/X11; do
 261                 case x"$FC_ADD_FONTS" in
 262                 x)
 263                         if test -d "$dir/fonts"; then
 264                                 for sub in "$dir"/fonts/*; do
 265                                         if ls "$sub" | grep -q -i '\.pf\|\.tt\|\.ot'; then
 266                                                 case x$FC_ADD_FONTS in
 267                                                 x)
 268                                                         FC_ADD_FONTS="$sub"
 269                                                         ;;
 270                                                 *)
 271                                                         FC_ADD_FONTS="$FC_ADD_FONTS,$sub"
 272                                                         ;;
 273                                                 esac
 274                                         fi
 275                                 done
 276                         fi
 277                         ;;
 278                 esac
 279         done
 280         AC_DEFINE_UNQUOTED(FC_ADD_FONTS,"$add_fonts",[Additional font directories])
 281         ;;
 282 no)
 283         FC_ADD_FONTS=""
 284         ;;
 285 *)
 286         FC_ADD_FONTS="$add_fonts"
 287         AC_DEFINE_UNQUOTED(FC_ADD_FONTS,"$add_fonts",[Additional font directories])
 288         ;;
 289 esac
 290
 291 AC_SUBST(FC_ADD_FONTS)
 292
 293 FC_FONTPATH=""
 294
 295 case "$FC_ADD_FONTS" in
 296 "")
 297         ;;
 298 *)
 299         FC_FONTPATH=`echo $FC_ADD_FONTS |
 300                         sed -e 's/^/<dir>/' -e 's/$/<\/dir>/' -e 's/,/<\/dir> <dir>/g'`
 301         ;;
 302 esac
 303
 304 AC_SUBST(FC_FONTPATH)
 305
 306 FC_FONTDATE=`date`
 307
 308 AC_SUBST(FC_FONTDATE)
 309
 310 AC_ARG_WITH(confdir,           [  --with-confdir=DIR            Use DIR to store configuration files (default /etc/fonts)], confdir="$withval", confdir=yes)
 311
 312 #
 313 # Set CONFDIR and FONTCONFIG_PATH
 314 #
 315
 316 case "$confdir" in
 317 no|yes)
 318         confdir='${sysconfdir}'/fonts
 319         ;;
 320 *)
 321         ;;
 322 esac
 323 AC_SUBST(confdir)
 324 CONFDIR=${confdir}
 325 AC_DEFINE_UNQUOTED(CONFDIR, "$CONFDIR",[Font configuration directory])
 326 AC_SUBST(CONFDIR)
 327
 328 #
 329 # Find out what language orthographies are included
 330 #
 331
 332 ORTH_FILES=`cd fc-lang && echo *.orth`
 333 AC_SUBST(ORTH_FILES)
 334
 335 #
 336 # Let people not build/install docs if they don't have docbook
 337 #
 338
 339 AC_CHECK_PROG(HASDOCBOOK, docbook2html, yes, no)
 340
 341 AM_CONDITIONAL(USEDOCBOOK, test "x$HASDOCBOOK" = xyes)
 342
 343 default_docs="yes"
 344 #
 345 # Check if docs exist or can be created
 346 #
 347 if test x$HASDOCBOOK = xno; then
 348         if test -f doc/fonts-conf.5; then
 349                 :
 350         else
 351                 default_docs="no"
 352         fi
 353 fi
 354
 355 AC_ARG_ENABLE(docs,           [  --disable-docs                Don't build and install documentation],,enable_docs=$default_docs)
 356
 357 AM_CONDITIONAL(ENABLE_DOCS, test "x$enable_docs" = xyes)
 358
 359 if test "x$enable_docs" = xyes; then
 360         DOCSRC="doc"
 361 else
 362         DOCSRC=""
 363 fi
 364
 365 AC_SUBST(DOCSRC)
 366
 367 #
 368 # Figure out where to install documentation
 369 #
 370
 371 AC_ARG_WITH(docdir,           [  --with-docdir=DIR             Use DIR to store documentation files (default ${datadir}/doc/fontconfig)], confdir="$withval")
 372
 373 if test "x$with_docdir" = "x" ; then
 374   DOCDIR='${datadir}/doc/fontconfig'
 375 else
 376   DOCDIR=$with_docdir
 377 fi
 378
 379 AC_SUBST(DOCDIR)
 380
 381 AC_OUTPUT([
 382 Makefile
 383 fontconfig/Makefile
 384 fc-lang/Makefile
 385 fc-glyphname/Makefile
 386 src/Makefile
 387 src/fontconfig.def
 388 fc-cache/Makefile
 389 fc-list/Makefile
 390 fc-match/Makefile
 391 doc/Makefile
 392 doc/version.sgml
 393 test/Makefile
 394 fontconfig.spec
 395 fontconfig.pc
 396 fonts.conf
 397 fontconfig-zip
 398 ])