configure.in

   1 dnl
   2 dnl  $Id$
   3 dnl
   4 dnl  Copyright © 2003 Keith Packard
   5 dnl
   6 dnl  Permission to use, copy, modify, distribute, and sell this software and its
   7 dnl  documentation for any purpose is hereby granted without fee, provided that
   8 dnl  the above copyright notice appear in all copies and that both that
   9 dnl  copyright notice and this permission notice appear in supporting
  10 dnl  documentation, and that the name of Keith Packard not be used in
  11 dnl  advertising or publicity pertaining to distribution of the software without
  12 dnl  specific, written prior permission.  Keith Packard makes no
  13 dnl  representations about the suitability of this software for any purpose.  It
  14 dnl  is provided "as is" without express or implied warranty.
  15 dnl
  16 dnl  KEITH PACKARD DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
  17 dnl  INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
  18 dnl  EVENT SHALL KEITH PACKARD BE LIABLE FOR ANY SPECIAL, INDIRECT OR
  19 dnl  CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
  20 dnl  DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
  21 dnl  TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
  22 dnl  PERFORMANCE OF THIS SOFTWARE.
  23 dnl
  24 dnl Process this file with autoconf to create configure.
  25
  26 AC_INIT(fonts.dtd)
  27
  28 dnl ==========================================================================
  29 dnl                               Versioning
  30 dnl ==========================================================================
  31
  32 dnl This is the package version number, not the shared library
  33 dnl version.  This same version number must appear in fontconfig/fontconfig.h
  34 dnl Yes, it is a pain to synchronize version numbers.  Unfortunately, it's
  35 dnl not possible to extract the version number here from fontconfig.h
  36 AM_INIT_AUTOMAKE(fontconfig, 2.2.96)
  37 AM_MAINTAINER_MODE
  38
  39 dnl libtool versioning
  40
  41 LT_CURRENT=1
  42 LT_REVISION=4
  43 AC_SUBST(LT_CURRENT)
  44 AC_SUBST(LT_REVISION)
  45 LT_AGE=0
  46
  47 LT_VERSION_INFO="$LT_CURRENT:$LT_REVISION:$LT_AGE"
  48 AC_SUBST(LT_VERSION_INFO)
  49
  50 LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
  51 AC_SUBST(LT_CURRENT_MINUS_AGE)
  52
  53 dnl ==========================================================================
  54
  55 AM_CONFIG_HEADER(config.h)
  56
  57 AC_PROG_CC
  58 AC_PROG_INSTALL
  59 AC_PROG_LN_S
  60 AC_LIBTOOL_WIN32_DLL
  61 AM_PROG_LIBTOOL
  62 AC_PROG_MAKE_SET
  63
  64 dnl ==========================================================================
  65
  66 case "$host" in
  67   *-*-mingw*)
  68     os_win32=yes
  69     ;;
  70   *)
  71     os_win32=no
  72 esac
  73 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
  74
  75 if test "$os_win32" = "yes"; then
  76   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
  77 fi
  78 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
  79
  80 WARN_CFLAGS=""
  81
  82 if test "x$GCC" = "xyes"; then
  83         WARN_CFLAGS="-Wall -Wpointer-arith -Wstrict-prototypes \
  84         -Wmissing-prototypes -Wmissing-declarations \
  85         -Wnested-externs -fno-strict-aliasing"
  86 fi
  87 AC_SUBST(WARN_CFLAGS)
  88
  89 dnl ==========================================================================
  90
  91 # Checks for header files.
  92 AC_HEADER_DIRENT
  93 AC_HEADER_STDC
  94 AC_CHECK_HEADERS([fcntl.h stdlib.h string.h unistd.h])
  95
  96 # Checks for typedefs, structures, and compiler characteristics.
  97 AC_C_CONST
  98 AC_TYPE_PID_T
  99
 100 # Checks for library functions.
 101 AC_FUNC_VPRINTF
 102 AC_CHECK_FUNCS([geteuid getuid link memmove memset mkstemp strchr strrchr strtol getopt getopt_long])
 103
 104 #
 105 # Checks for FreeType
 106 #
 107
 108 AC_ARG_WITH(freetype-config, [  --with-freetype-config=PROG   Use FreeType configuration program PROG], freetype_config=$withval, freetype_config=yes)
 109
 110 if test "$freetype_config" = "yes"; then
 111         AC_PATH_PROG(ft_config,freetype-config,no)
 112         if test "$ft_config" = "no"; then
 113                 AC_MSG_ERROR([You must have freetype installed; see http://www.freetype.org/])
 114         fi
 115 else
 116         ft_config="$freetype_config"
 117 fi
 118
 119 FREETYPE_CFLAGS="`$ft_config --cflags`"
 120 FREETYPE_LIBS="`$ft_config --libs`"
 121
 122 AC_SUBST(FREETYPE_LIBS)
 123 AC_SUBST(FREETYPE_CFLAGS)
 124
 125 #
 126 # Check to see whether we have:
 127 #  FT_Get_Next_Char
 128 #  FT_Get_BDF_Property
 129 #  FT_Get_PS_Font_Info
 130 #  FT_Has_PS_Glyph_Names
 131 #
 132
 133 fontconfig_save_libs="$LIBS"
 134 fontconfig_save_cflags="$CFLAGS"
 135 LIBS="$LIBS $FREETYPE_LIBS"
 136 CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
 137 AC_CHECK_FUNCS(FT_Get_Next_Char FT_Get_BDF_Property FT_Get_PS_Font_Info FT_Has_PS_Glyph_Names)
 138 AC_CHECK_MEMBER(FT_Bitmap_Size.y_ppem,
 139                 HAVE_FT_BITMAP_SIZE_Y_PPEM=1,
 140                 HAVE_FT_BITMAP_SIZE_Y_PPEM=0,
 141 [#include <ft2build.h>
 142 #include FT_FREETYPE_H])
 143 AC_DEFINE_UNQUOTED(HAVE_FT_BITMAP_SIZE_Y_PPEM,$HAVE_FT_BITMAP_SIZE_Y_PPEM,
 144                    [FT_Bitmap_Size structure includes y_ppem field])
 145 CFLAGS="$fontconfig_save_cflags"
 146 LIBS="$fontconfig_save_libs"
 147
 148 #
 149 # Check expat configuration
 150 #
 151
 152 AC_ARG_WITH(expat,             [  --with-expat=DIR              Use Expat in DIR], expat=$withval, expat=yes)
 153 AC_ARG_WITH(expat-includes,    [  --with-expat-includes=DIR     Use Expat includes in DIR], expat_includes=$withval, expat_includes=yes)
 154 AC_ARG_WITH(expat-lib,         [  --with-expat-lib=DIR          Use Expat library in DIR], expat_lib=$withval, expat_lib=yes)
 155
 156 case "$expat" in
 157 no)
 158         ;;
 159 *)
 160         case "$expat_includes" in
 161         yes|no)
 162                 EXPAT_CFLAGS=""
 163                 ;;
 164         *)
 165                 EXPAT_CFLAGS="-I$expat_includes"
 166                 ;;
 167         esac
 168         case "$expat_lib" in
 169         yes)
 170                 case "$expat" in
 171                 yes)
 172                         EXPAT_LIBS="-lexpat"
 173                         ;;
 174                 *)
 175                         EXPAT_LIBS="-L$expat/lib -lexpat"
 176                         ;;
 177                 esac
 178                 ;;
 179         no)
 180                 ;;
 181         *)
 182                 EXPAT_LIBS="-L$expat_lib -lexpat"
 183                 ;;
 184         esac
 185
 186         expatsaved_CPPFLAGS="$CPPFLAGS"
 187         CPPFLAGS="$CPPFLAGS $EXPAT_CFLAGS"
 188         expatsaved_LIBS="$LIBS"
 189         LIBS="$LIBS $EXPAT_LIBS"
 190
 191         AC_CHECK_HEADER(expat.h)
 192         case "$ac_cv_header_expat_h" in
 193         no)
 194                 AC_CHECK_HEADER(xmlparse.h)
 195                 case "$ac_cv_header_xmlparse_h" in
 196                 no)
 197                         have_expat_header=no;
 198                         ;;
 199                 yes)
 200                         HAVE_XMLPARSE_H=1
 201                         AC_SUBST(HAVE_XMLPARSE_H)
 202                         AC_DEFINE_UNQUOTED(HAVE_XMLPARSE_H,$HAVE_XMLPARSE_H,
 203                         [Use xmlparse.h instead of expat.h])
 204                         have_expat_header=yes
 205                         ;;
 206                 esac
 207                 ;;
 208         yes)
 209                 have_expat_header=yes
 210                 ;;
 211         esac
 212         case "$have_expat_header" in
 213         no)
 214                 expat=no
 215                 ;;
 216         yes)
 217                 AC_CHECK_FUNCS(XML_SetDoctypeDeclHandler)
 218                 case "$ac_cv_func_XML_SetDoctypeDeclHandler" in
 219                 yes)
 220                         HAVE_EXPAT=1
 221                         AC_SUBST(HAVE_EXPAT)
 222                         AC_DEFINE_UNQUOTED(HAVE_EXPAT,$HAVE_EXPAT,
 223                         [Found a useable expat library])
 224                         ;;
 225                 *)
 226                         expat=no
 227                         ;;
 228                 esac
 229                 ;;
 230         esac
 231         CPPFLAGS="$expatsaved_CPPFLAGS"
 232         LIBS="$expatsaved_LIBS"
 233         ;;
 234 esac
 235 AC_SUBST(EXPAT_LIBS)
 236 AC_SUBST(EXPAT_CFLAGS)
 237
 238 case "$expat" in
 239 no)
 240         AC_MSG_ERROR([Cannot find usable expat library. This could mean that your version is too old.])
 241         ;;
 242 esac
 243
 244 #
 245 # Set default font directory
 246 #
 247
 248 AC_ARG_WITH(default-fonts,     [  --with-default-fonts=DIR      Use fonts from DIR when config is busted], default_fonts="$withval", default_fonts=yes)
 249
 250 case "$default_fonts" in
 251 yes)
 252         if test "$os_win32" = "yes"; then
 253                 FC_DEFAULT_FONTS="WINDOWSFONTDIR"
 254                 AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "WINDOWSFONTDIR",
 255                                    [Windows font directory])
 256         else
 257                 FC_DEFAULT_FONTS="/usr/share/fonts"
 258                 AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "/usr/share/fonts",
 259                                    [System font directory])
 260         fi
 261         ;;
 262 *)
 263         FC_DEFAULT_FONTS="$default_fonts"
 264         AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "$default_fonts",
 265                            [System font directory])
 266         ;;
 267 esac
 268
 269 AC_SUBST(FC_DEFAULT_FONTS)
 270
 271 #
 272 # Add more fonts if available.  By default, add only the directories
 273 # with outline fonts; those with bitmaps can be added as desired in
 274 # local.conf or ~/.fonts.conf
 275 #
 276 AC_ARG_WITH(add-fonts,        [  --with-add-fonts=DIR1,DIR2,...Find additional fonts in DIR1,DIR2,... ], add_fonts="$withval", add_fonts=yes)
 277
 278 case "$add_fonts" in
 279 yes)
 280         FC_ADD_FONTS=""
 281         for dir in /usr/X11R6/lib/X11 /usr/X11/lib/X11 /usr/lib/X11; do
 282                 case x"$FC_ADD_FONTS" in
 283                 x)
 284                         if test -d "$dir/fonts"; then
 285                                 for sub in "$dir"/fonts/*; do
 286                                         if ls "$sub" | grep -q -i '\.pf\|\.tt\|\.ot'; then
 287                                                 case x$FC_ADD_FONTS in
 288                                                 x)
 289                                                         FC_ADD_FONTS="$sub"
 290                                                         ;;
 291                                                 *)
 292                                                         FC_ADD_FONTS="$FC_ADD_FONTS,$sub"
 293                                                         ;;
 294                                                 esac
 295                                         fi
 296                                 done
 297                         fi
 298                         ;;
 299                 esac
 300         done
 301         AC_DEFINE_UNQUOTED(FC_ADD_FONTS,"$add_fonts",[Additional font directories])
 302         ;;
 303 no)
 304         FC_ADD_FONTS=""
 305         ;;
 306 *)
 307         FC_ADD_FONTS="$add_fonts"
 308         AC_DEFINE_UNQUOTED(FC_ADD_FONTS,"$add_fonts",[Additional font directories])
 309         ;;
 310 esac
 311
 312 AC_SUBST(FC_ADD_FONTS)
 313
 314 FC_FONTPATH=""
 315
 316 case "$FC_ADD_FONTS" in
 317 "")
 318         ;;
 319 *)
 320         FC_FONTPATH=`echo $FC_ADD_FONTS |
 321                         sed -e 's/^/<dir>/' -e 's/$/<\/dir>/' -e 's/,/<\/dir> <dir>/g'`
 322         ;;
 323 esac
 324
 325 AC_SUBST(FC_FONTPATH)
 326
 327 FC_FONTDATE=`date`
 328
 329 AC_SUBST(FC_FONTDATE)
 330
 331 AC_ARG_WITH(confdir,           [  --with-confdir=DIR            Use DIR to store configuration files (default /etc/fonts)], confdir="$withval", confdir=yes)
 332
 333 #
 334 # Set CONFDIR and FONTCONFIG_PATH
 335 #
 336
 337 case "$confdir" in
 338 no|yes)
 339         confdir='${sysconfdir}'/fonts
 340         ;;
 341 *)
 342         ;;
 343 esac
 344 AC_SUBST(confdir)
 345 CONFDIR=${confdir}
 346 AC_DEFINE_UNQUOTED(CONFDIR, "$CONFDIR",[Font configuration directory])
 347 AC_SUBST(CONFDIR)
 348
 349 #
 350 # Find out what language orthographies are included
 351 #
 352
 353 ORTH_FILES=`cd ${srcdir}/fc-lang && echo *.orth`
 354 AC_SUBST(ORTH_FILES)
 355
 356 #
 357 # Let people not build/install docs if they don't have docbook
 358 #
 359
 360 AC_CHECK_PROG(HASDOCBOOK, docbook2html, yes, no)
 361
 362 AM_CONDITIONAL(USEDOCBOOK, test "x$HASDOCBOOK" = xyes)
 363
 364 default_docs="yes"
 365 #
 366 # Check if docs exist or can be created
 367 #
 368 if test x$HASDOCBOOK = xno; then
 369         if test -f doc/fonts-conf.5; then
 370                 :
 371         else
 372                 default_docs="no"
 373         fi
 374 fi
 375
 376 AC_ARG_ENABLE(docs,           [  --disable-docs                Don't build and install documentation],,enable_docs=$default_docs)
 377
 378 AM_CONDITIONAL(ENABLE_DOCS, test "x$enable_docs" = xyes)
 379
 380 if test "x$enable_docs" = xyes; then
 381         DOCSRC="doc"
 382         tmp=funcs.$$
 383         cat $srcdir/doc/*.fncs | awk '
 384         /^@TITLE@/      { if (!done) { printf ("%s\n", $2); done = 1; } }
 385         /^@FUNC@/       { if (!done) { printf ("%s\n", $2); done = 1; } }
 386         /^@@/           { done = 0; }' > $tmp
 387         DOCMAN3=`cat $tmp | awk '{ printf ("%s.3 ", $1); }'`
 388         echo DOCMAN3 $DOCMAN3
 389         rm -f $tmp
 390 else
 391         DOCSRC=""
 392         DOCMAN3=""
 393 fi
 394
 395 AC_SUBST(DOCSRC)
 396 AC_SUBST(DOCMAN3)
 397
 398 #
 399 # Figure out where to install documentation
 400 #
 401
 402 AC_ARG_WITH(docdir,           [  --with-docdir=DIR             Use DIR to store documentation files (default ${datadir}/doc/fontconfig)], confdir="$withval")
 403
 404 if test "x$with_docdir" = "x" ; then
 405   DOCDIR='${datadir}/doc/fontconfig'
 406 else
 407   DOCDIR=$with_docdir
 408 fi
 409
 410 AC_SUBST(DOCDIR)
 411
 412 AC_OUTPUT([
 413 Makefile
 414 fontconfig/Makefile
 415 fc-lang/Makefile
 416 fc-glyphname/Makefile
 417 src/Makefile
 418 src/fontconfig.def
 419 fc-cache/Makefile
 420 fc-list/Makefile
 421 fc-match/Makefile
 422 doc/Makefile
 423 doc/version.sgml
 424 test/Makefile
 425 fontconfig.spec
 426 fontconfig.pc
 427 fonts.conf
 428 fontconfig-zip
 429 ])