configure.in

   1 dnl
   2 dnl  $Id$
   3 dnl
   4 dnl  Copyright © 2003 Keith Packard
   5 dnl
   6 dnl  Permission to use, copy, modify, distribute, and sell this software and its
   7 dnl  documentation for any purpose is hereby granted without fee, provided that
   8 dnl  the above copyright notice appear in all copies and that both that
   9 dnl  copyright notice and this permission notice appear in supporting
  10 dnl  documentation, and that the name of Keith Packard not be used in
  11 dnl  advertising or publicity pertaining to distribution of the software without
  12 dnl  specific, written prior permission.  Keith Packard makes no
  13 dnl  representations about the suitability of this software for any purpose.  It
  14 dnl  is provided "as is" without express or implied warranty.
  15 dnl
  16 dnl  KEITH PACKARD DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
  17 dnl  INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
  18 dnl  EVENT SHALL KEITH PACKARD BE LIABLE FOR ANY SPECIAL, INDIRECT OR
  19 dnl  CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
  20 dnl  DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
  21 dnl  TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
  22 dnl  PERFORMANCE OF THIS SOFTWARE.
  23 dnl
  24 dnl Process this file with autoconf to create configure.
  25
  26 AC_INIT(fonts.dtd)
  27
  28 dnl ==========================================================================
  29 dnl                               Versioning
  30 dnl ==========================================================================
  31
  32 dnl This is the package version number, not the shared library
  33 dnl version.  This same version number must appear in fontconfig/fontconfig.h
  34 dnl Yes, it is a pain to synchronize version numbers.  Unfortunately, it's
  35 dnl not possible to extract the version number here from fontconfig.h
  36 AM_INIT_AUTOMAKE(fontconfig, 2.3.94)
  37 AM_MAINTAINER_MODE
  38
  39 dnl libtool versioning
  40
  41 LT_CURRENT=1
  42 LT_REVISION=4
  43 AC_SUBST(LT_CURRENT)
  44 AC_SUBST(LT_REVISION)
  45 LT_AGE=0
  46
  47 LT_VERSION_INFO="$LT_CURRENT:$LT_REVISION:$LT_AGE"
  48 AC_SUBST(LT_VERSION_INFO)
  49
  50 LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
  51 AC_SUBST(LT_CURRENT_MINUS_AGE)
  52
  53 dnl ==========================================================================
  54
  55 AM_CONFIG_HEADER(config.h)
  56
  57 AC_PROG_CC
  58 AC_PROG_INSTALL
  59 AC_PROG_LN_S
  60 AC_LIBTOOL_WIN32_DLL
  61 AM_PROG_LIBTOOL
  62 AC_PROG_MAKE_SET
  63
  64 dnl ==========================================================================
  65
  66 case "$host" in
  67   *-*-mingw*)
  68     os_win32=yes
  69     ;;
  70   *)
  71     os_win32=no
  72 esac
  73 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
  74
  75 if test "$os_win32" = "yes"; then
  76   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
  77 fi
  78 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
  79
  80 WARN_CFLAGS=""
  81
  82 if test "x$GCC" = "xyes"; then
  83         WARN_CFLAGS="-Wall -Wpointer-arith -Wstrict-prototypes \
  84         -Wmissing-prototypes -Wmissing-declarations \
  85         -Wnested-externs -fno-strict-aliasing"
  86 fi
  87 AC_SUBST(WARN_CFLAGS)
  88
  89 dnl ==========================================================================
  90
  91 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
  92
  93 dnl ==========================================================================
  94
  95 # Setup for compiling build tools (fc-glyphname, etc)
  96 AC_MSG_CHECKING([for a C compiler for build tools])
  97 if test $cross_compiling = yes; then
  98   AC_CHECK_PROGS(CC_FOR_BUILD, gcc cc)
  99 else
 100   CC_FOR_BUILD=$CC
 101 fi
 102 AC_MSG_RESULT([$CC_FOR_BUILD])
 103 AC_SUBST(CC_FOR_BUILD)
 104
 105 AC_MSG_CHECKING([for suffix of executable build tools])
 106 if test $cross_compiling = yes; then
 107   cat >conftest.c <<\_______EOF
 108 int
 109 main ()
 110 {
 111   exit (0);
 112 }
 113 _______EOF
 114   for i in .exe ""; do
 115     compile="$CC_FOR_BUILD conftest.c -o conftest$i"
 116     if AC_TRY_EVAL(compile); then
 117       if (./conftest) 2>&AC_FD_CC; then
 118         EXEEXT_FOR_BUILD=$i
 119         break
 120       fi
 121     fi
 122   done
 123   rm -f conftest*
 124   if test "${EXEEXT_FOR_BUILD+set}" != set; then
 125     AC_MSG_ERROR([Cannot determine suffix of executable build tools])
 126   fi
 127 else
 128   EXEEXT_FOR_BUILD=$EXEEXT
 129 fi
 130 AC_MSG_RESULT([$EXEEXT_FOR_BUILD])
 131 AC_SUBST(EXEEXT_FOR_BUILD)
 132
 133 dnl ==========================================================================
 134
 135 # Checks for header files.
 136 AC_HEADER_DIRENT
 137 AC_HEADER_STDC
 138 AC_CHECK_HEADERS([fcntl.h stdlib.h string.h unistd.h iconv.h])
 139
 140 # Checks for typedefs, structures, and compiler characteristics.
 141 AC_C_CONST
 142 AC_TYPE_PID_T
 143
 144 # Checks for library functions.
 145 AC_FUNC_VPRINTF
 146 AC_FUNC_MMAP
 147 AC_CHECK_FUNCS([geteuid getuid link memmove memset mkstemp strchr strrchr strtol getopt getopt_long iconv sysconf ftruncate chsize rand_r])
 148
 149 #
 150 # Checks for FreeType
 151 #
 152
 153 AC_ARG_WITH(freetype-config, [  --with-freetype-config=PROG   Use FreeType configuration program PROG], freetype_config=$withval, freetype_config=yes)
 154
 155 if test "$freetype_config" = "yes"; then
 156         AC_PATH_PROG(ft_config,freetype-config,no)
 157         if test "$ft_config" = "no"; then
 158                 AC_MSG_ERROR([You must have freetype installed; see http://www.freetype.org/])
 159         fi
 160 else
 161         ft_config="$freetype_config"
 162 fi
 163
 164 FREETYPE_CFLAGS="`$ft_config --cflags`"
 165 FREETYPE_LIBS="`$ft_config --libs`"
 166
 167 AC_SUBST(FREETYPE_LIBS)
 168 AC_SUBST(FREETYPE_CFLAGS)
 169
 170 #
 171 # Check to see whether we have:
 172 #  FT_Get_Next_Char
 173 #  FT_Get_BDF_Property
 174 #  FT_Get_PS_Font_Info
 175 #  FT_Has_PS_Glyph_Names
 176 #
 177
 178 fontconfig_save_libs="$LIBS"
 179 fontconfig_save_cflags="$CFLAGS"
 180 LIBS="$LIBS $FREETYPE_LIBS"
 181 CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
 182 AC_CHECK_FUNCS(FT_Get_Next_Char FT_Get_BDF_Property FT_Get_PS_Font_Info FT_Has_PS_Glyph_Names FT_Get_X11_Font_Format)
 183 AC_CHECK_MEMBER(FT_Bitmap_Size.y_ppem,
 184                 HAVE_FT_BITMAP_SIZE_Y_PPEM=1,
 185                 HAVE_FT_BITMAP_SIZE_Y_PPEM=0,
 186 [#include <ft2build.h>
 187 #include FT_FREETYPE_H])
 188 AC_DEFINE_UNQUOTED(HAVE_FT_BITMAP_SIZE_Y_PPEM,$HAVE_FT_BITMAP_SIZE_Y_PPEM,
 189                    [FT_Bitmap_Size structure includes y_ppem field])
 190 CFLAGS="$fontconfig_save_cflags"
 191 LIBS="$fontconfig_save_libs"
 192
 193 #
 194 # Check expat configuration
 195 #
 196
 197 AC_ARG_WITH(expat,             [  --with-expat=DIR              Use Expat in DIR], expat=$withval, expat=yes)
 198 AC_ARG_WITH(expat-includes,    [  --with-expat-includes=DIR     Use Expat includes in DIR], expat_includes=$withval, expat_includes=yes)
 199 AC_ARG_WITH(expat-lib,         [  --with-expat-lib=DIR          Use Expat library in DIR], expat_lib=$withval, expat_lib=yes)
 200
 201 if test "$enable_libxml2" != "yes"; then
 202         case "$expat" in
 203         no)
 204         ;;
 205         *)
 206                 case "$expat_includes" in
 207                 yes)
 208                         case "$expat" in
 209                         yes)
 210                                 ;;
 211                         *)
 212                                 EXPAT_CFLAGS="-I$expat/include"
 213                                 ;;
 214                         esac
 215                         ;;
 216                 no)
 217                         EXPAT_CFLAGS=""
 218                         ;;
 219                 *)
 220                         EXPAT_CFLAGS="-I$expat_includes"
 221                         ;;
 222                 esac
 223                 case "$expat_lib" in
 224                 yes)
 225                         case "$expat" in
 226                         yes)
 227                                 EXPAT_LIBS="-lexpat"
 228                                 ;;
 229                         *)
 230                                 EXPAT_LIBS="-L$expat/lib -lexpat"
 231                                 ;;
 232                         esac
 233                         ;;
 234                 no)
 235                         ;;
 236                 *)
 237                         EXPAT_LIBS="-L$expat_lib -lexpat"
 238                         ;;
 239                 esac
 240
 241                 expatsaved_CPPFLAGS="$CPPFLAGS"
 242                 CPPFLAGS="$CPPFLAGS $EXPAT_CFLAGS"
 243                 expatsaved_LIBS="$LIBS"
 244                 LIBS="$LIBS $EXPAT_LIBS"
 245
 246                 AC_CHECK_HEADER(expat.h)
 247                 case "$ac_cv_header_expat_h" in
 248                 no)
 249                         AC_CHECK_HEADER(xmlparse.h)
 250                         case "$ac_cv_header_xmlparse_h" in
 251                         no)
 252                                 have_expat_header=no;
 253                                 ;;
 254                         yes)
 255                                 HAVE_XMLPARSE_H=1
 256                                 AC_SUBST(HAVE_XMLPARSE_H)
 257                                 AC_DEFINE_UNQUOTED(HAVE_XMLPARSE_H,$HAVE_XMLPARSE_H,
 258                                 [Use xmlparse.h instead of expat.h])
 259                                 have_expat_header=yes
 260                                 ;;
 261                         esac
 262                         ;;
 263                 yes)
 264                         have_expat_header=yes
 265                         ;;
 266                 esac
 267                 case "$have_expat_header" in
 268                 no)
 269                         expat=no
 270                         ;;
 271                 yes)
 272                         AC_CHECK_FUNCS(XML_SetDoctypeDeclHandler)
 273                         case "$ac_cv_func_XML_SetDoctypeDeclHandler" in
 274                         yes)
 275                                 HAVE_EXPAT=1
 276                                 AC_SUBST(HAVE_EXPAT)
 277                                 AC_DEFINE_UNQUOTED(HAVE_EXPAT,$HAVE_EXPAT,
 278                                 [Found a useable expat library])
 279                                 ;;
 280                         *)
 281                                 expat=no
 282                                 ;;
 283                         esac
 284                         ;;
 285                 esac
 286                 CPPFLAGS="$expatsaved_CPPFLAGS"
 287                 LIBS="$expatsaved_LIBS"
 288                 ;;
 289         esac
 290
 291         AC_SUBST(EXPAT_CFLAGS)
 292         AC_SUBST(EXPAT_LIBS)
 293
 294         case "$expat" in
 295         no)
 296                 EXPAT_CFLAGS=""
 297                 EXPAT_LIBS=""
 298
 299                 AC_MSG_WARN([Cannot find usable expat library. Trying to use libxml2 as fallback.])
 300                 ;;
 301         esac
 302 fi
 303
 304 #
 305 # Check libxml2 configuration
 306 #
 307
 308 AC_ARG_ENABLE(libxml2,         [  --enable-libxml2              Use libxml2 instead of Expat])
 309
 310 PKG_PROG_PKG_CONFIG
 311
 312 if test "$enable_libxml2" = "yes" -o "$expat" = "no"; then
 313     PKG_CHECK_MODULES([LIBXML2], [libxml-2.0 >= 2.6])
 314     AC_DEFINE_UNQUOTED(ENABLE_LIBXML2,1,[Use libxml2 instead of Expat])
 315
 316     AC_SUBST(LIBXML2_CFLAGS)
 317     AC_SUBST(LIBXML2_LIBS)
 318 fi
 319
 320 #
 321 # Set default font directory
 322 #
 323
 324 AC_ARG_WITH(default-fonts,     [  --with-default-fonts=DIR      Use fonts from DIR when config is busted], default_fonts="$withval", default_fonts=yes)
 325
 326 case "$default_fonts" in
 327 yes)
 328         if test "$os_win32" = "yes"; then
 329                 FC_DEFAULT_FONTS="WINDOWSFONTDIR"
 330                 AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "WINDOWSFONTDIR",
 331                                    [Windows font directory])
 332         else
 333                 FC_DEFAULT_FONTS="/usr/share/fonts"
 334                 AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "/usr/share/fonts",
 335                                    [System font directory])
 336         fi
 337         ;;
 338 *)
 339         FC_DEFAULT_FONTS="$default_fonts"
 340         AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "$default_fonts",
 341                            [System font directory])
 342         ;;
 343 esac
 344
 345 AC_SUBST(FC_DEFAULT_FONTS)
 346
 347 #
 348 # Add more fonts if available.  By default, add only the directories
 349 # with outline fonts; those with bitmaps can be added as desired in
 350 # local.conf or ~/.fonts.conf
 351 #
 352 AC_ARG_WITH(add-fonts,        [  --with-add-fonts=DIR1,DIR2,...Find additional fonts in DIR1,DIR2,... ], add_fonts="$withval", add_fonts=yes)
 353
 354 case "$add_fonts" in
 355 yes)
 356         FC_ADD_FONTS=""
 357         for dir in /usr/X11R6/lib/X11 /usr/X11/lib/X11 /usr/lib/X11; do
 358                 case x"$FC_ADD_FONTS" in
 359                 x)
 360                         sub="$dir/fonts"
 361                         if test -d "$sub"; then
 362                                 case x$FC_ADD_FONTS in
 363                                 x)
 364                                         FC_ADD_FONTS="$sub"
 365                                         ;;
 366                                 *)
 367                                         FC_ADD_FONTS="$FC_ADD_FONTS,$sub"
 368                                         ;;
 369                                 esac
 370                         fi
 371                         ;;
 372                 esac
 373         done
 374         AC_DEFINE_UNQUOTED(FC_ADD_FONTS,"$add_fonts",[Additional font directories])
 375         ;;
 376 no)
 377         FC_ADD_FONTS=""
 378         ;;
 379 *)
 380         FC_ADD_FONTS="$add_fonts"
 381         AC_DEFINE_UNQUOTED(FC_ADD_FONTS,"$add_fonts",[Additional font directories])
 382         ;;
 383 esac
 384
 385 AC_SUBST(FC_ADD_FONTS)
 386
 387 FC_FONTPATH=""
 388
 389 case "$FC_ADD_FONTS" in
 390 "")
 391         ;;
 392 *)
 393         FC_FONTPATH=`echo $FC_ADD_FONTS |
 394                         sed -e 's/^/<dir>/' -e 's/$/<\/dir>/' -e 's/,/<\/dir> <dir>/g'`
 395         ;;
 396 esac
 397
 398 AC_SUBST(FC_FONTPATH)
 399
 400 FC_FONTDATE=`LC_ALL=C date`
 401
 402 AC_SUBST(FC_FONTDATE)
 403
 404 AC_ARG_WITH(confdir,           [  --with-confdir=DIR            Use DIR to store configuration files (default /etc/fonts)], confdir="$withval", confdir=yes)
 405
 406 #
 407 # Set CONFDIR and FONTCONFIG_PATH
 408 #
 409
 410 case "$confdir" in
 411 no|yes)
 412         confdir='${sysconfdir}'/fonts
 413         ;;
 414 *)
 415         ;;
 416 esac
 417 AC_SUBST(confdir)
 418 CONFDIR=${confdir}
 419 AC_DEFINE_UNQUOTED(CONFDIR, "$CONFDIR",[Font configuration directory])
 420 AC_SUBST(CONFDIR)
 421
 422 #
 423 # Find out what language orthographies are included
 424 #
 425
 426 ORTH_FILES=`cd ${srcdir}/fc-lang && echo *.orth`
 427 AC_SUBST(ORTH_FILES)
 428
 429 #
 430 # Let people not build/install docs if they don't have docbook
 431 #
 432
 433 AC_CHECK_PROG(HASDOCBOOK, docbook2html, yes, no)
 434
 435 AM_CONDITIONAL(USEDOCBOOK, test "x$HASDOCBOOK" = xyes)
 436
 437 default_docs="yes"
 438 #
 439 # Check if docs exist or can be created
 440 #
 441 if test x$HASDOCBOOK = xno; then
 442         if test -f doc/fonts-conf.5; then
 443                 :
 444         else
 445                 default_docs="no"
 446         fi
 447 fi
 448
 449 AC_ARG_ENABLE(docs,           [  --disable-docs                Don't build and install documentation],,enable_docs=$default_docs)
 450
 451 AM_CONDITIONAL(ENABLE_DOCS, test "x$enable_docs" = xyes)
 452
 453 if test "x$enable_docs" = xyes; then
 454         DOCSRC="doc"
 455         tmp=funcs.$$
 456         cat $srcdir/doc/*.fncs | awk '
 457         /^@TITLE@/      { if (!done) { printf ("%s\n", $2); done = 1; } }
 458         /^@FUNC@/       { if (!done) { printf ("%s\n", $2); done = 1; } }
 459         /^@@/           { done = 0; }' > $tmp
 460         DOCMAN3=`cat $tmp | awk '{ printf ("%s.3 ", $1); }'`
 461         echo DOCMAN3 $DOCMAN3
 462         rm -f $tmp
 463 else
 464         DOCSRC=""
 465         DOCMAN3=""
 466 fi
 467
 468 AC_SUBST(DOCSRC)
 469 AC_SUBST(DOCMAN3)
 470
 471 #
 472 # Figure out where to install documentation
 473 #
 474
 475 AC_ARG_WITH(docdir,           [  --with-docdir=DIR             Use DIR to store documentation files (default ${datadir}/doc/fontconfig)], confdir="$withval")
 476
 477 if test "x$with_docdir" = "x" ; then
 478   DOCDIR='${datadir}/doc/fontconfig'
 479 else
 480   DOCDIR=$with_docdir
 481 fi
 482
 483 AC_SUBST(DOCDIR)
 484
 485 #
 486 # Make /var/cache/fontconfig directory available to source code
 487 #
 488
 489 pkgcachedir='${localstatedir}/cache/'${PACKAGE}
 490 AC_SUBST(pkgcachedir)
 491
 492 AC_OUTPUT([
 493 Makefile
 494 fontconfig/Makefile
 495 fc-lang/Makefile
 496 fc-glyphname/Makefile
 497 fc-case/Makefile
 498 src/Makefile
 499 src/fontconfig.def
 500 conf.d/Makefile
 501 fc-cache/Makefile
 502 fc-cat/Makefile
 503 fc-list/Makefile
 504 fc-match/Makefile
 505 doc/Makefile
 506 doc/version.sgml
 507 test/Makefile
 508 fontconfig.spec
 509 fontconfig.pc
 510 fonts.conf
 511 fontconfig-zip
 512 ])