configure.in

   1 dnl
   2 dnl  $Id$
   3 dnl
   4 dnl  Copyright © 2003 Keith Packard
   5 dnl
   6 dnl  Permission to use, copy, modify, distribute, and sell this software and its
   7 dnl  documentation for any purpose is hereby granted without fee, provided that
   8 dnl  the above copyright notice appear in all copies and that both that
   9 dnl  copyright notice and this permission notice appear in supporting
  10 dnl  documentation, and that the name of Keith Packard not be used in
  11 dnl  advertising or publicity pertaining to distribution of the software without
  12 dnl  specific, written prior permission.  Keith Packard makes no
  13 dnl  representations about the suitability of this software for any purpose.  It
  14 dnl  is provided "as is" without express or implied warranty.
  15 dnl
  16 dnl  KEITH PACKARD DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
  17 dnl  INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
  18 dnl  EVENT SHALL KEITH PACKARD BE LIABLE FOR ANY SPECIAL, INDIRECT OR
  19 dnl  CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
  20 dnl  DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
  21 dnl  TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
  22 dnl  PERFORMANCE OF THIS SOFTWARE.
  23 dnl
  24 dnl Process this file with autoconf to create configure.
  25
  26 AC_INIT(fonts.dtd)
  27
  28 dnl ==========================================================================
  29 dnl                               Versioning
  30 dnl ==========================================================================
  31
  32 dnl This is the package version number, not the shared library
  33 dnl version.  This same version number must appear in fontconfig/fontconfig.h
  34 dnl Yes, it is a pain to synchronize version numbers.  Unfortunately, it's
  35 dnl not possible to extract the version number here from fontconfig.h
  36 AM_INIT_AUTOMAKE(fontconfig, 2.3.92)
  37 AM_MAINTAINER_MODE
  38
  39 dnl libtool versioning
  40
  41 LT_CURRENT=1
  42 LT_REVISION=4
  43 AC_SUBST(LT_CURRENT)
  44 AC_SUBST(LT_REVISION)
  45 LT_AGE=0
  46
  47 LT_VERSION_INFO="$LT_CURRENT:$LT_REVISION:$LT_AGE"
  48 AC_SUBST(LT_VERSION_INFO)
  49
  50 LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
  51 AC_SUBST(LT_CURRENT_MINUS_AGE)
  52
  53 dnl ==========================================================================
  54
  55 AM_CONFIG_HEADER(config.h)
  56
  57 AC_PROG_CC
  58 AC_PROG_INSTALL
  59 AC_PROG_LN_S
  60 AC_LIBTOOL_WIN32_DLL
  61 AM_PROG_LIBTOOL
  62 AC_PROG_MAKE_SET
  63
  64 dnl ==========================================================================
  65
  66 case "$host" in
  67   *-*-mingw*)
  68     os_win32=yes
  69     ;;
  70   *)
  71     os_win32=no
  72 esac
  73 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
  74
  75 if test "$os_win32" = "yes"; then
  76   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
  77 fi
  78 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
  79
  80 WARN_CFLAGS=""
  81
  82 if test "x$GCC" = "xyes"; then
  83         WARN_CFLAGS="-Wall -Wpointer-arith -Wstrict-prototypes \
  84         -Wmissing-prototypes -Wmissing-declarations \
  85         -Wnested-externs -fno-strict-aliasing"
  86 fi
  87 AC_SUBST(WARN_CFLAGS)
  88
  89 dnl ==========================================================================
  90
  91 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
  92
  93 dnl ==========================================================================
  94
  95 # Setup for compiling build tools (fc-glyphname, etc)
  96 AC_MSG_CHECKING([for a C compiler for build tools])
  97 if test $cross_compiling = yes; then
  98   AC_CHECK_PROGS(CC_FOR_BUILD, gcc cc)
  99 else
 100   CC_FOR_BUILD=$CC
 101 fi
 102 AC_MSG_RESULT([$CC_FOR_BUILD])
 103 AC_SUBST(CC_FOR_BUILD)
 104
 105 AC_MSG_CHECKING([for suffix of executable build tools])
 106 if test $cross_compiling = yes; then
 107   cat >conftest.c <<\_______EOF
 108 int
 109 main ()
 110 {
 111   exit (0);
 112 }
 113 _______EOF
 114   for i in .exe ""; do
 115     compile="$CC_FOR_BUILD conftest.c -o conftest$i"
 116     if AC_TRY_EVAL(compile); then
 117       if (./conftest) 2>&AC_FD_CC; then
 118         EXEEXT_FOR_BUILD=$i
 119         break
 120       fi
 121     fi
 122   done
 123   rm -f conftest*
 124   if test "${EXEEXT_FOR_BUILD+set}" != set; then
 125     AC_MSG_ERROR([Cannot determine suffix of executable build tools])
 126   fi
 127 else
 128   EXEEXT_FOR_BUILD=$EXEEXT
 129 fi
 130 AC_MSG_RESULT([$EXEEXT_FOR_BUILD])
 131 AC_SUBST(EXEEXT_FOR_BUILD)
 132
 133 dnl ==========================================================================
 134
 135 # Checks for header files.
 136 AC_HEADER_DIRENT
 137 AC_HEADER_STDC
 138 AC_CHECK_HEADERS([fcntl.h stdlib.h string.h unistd.h iconv.h])
 139
 140 # Checks for typedefs, structures, and compiler characteristics.
 141 AC_C_CONST
 142 AC_TYPE_PID_T
 143
 144 # Checks for library functions.
 145 AC_FUNC_VPRINTF
 146 AC_CHECK_FUNCS([geteuid getuid link memmove memset mkstemp strchr strrchr strtol getopt getopt_long iconv])
 147
 148 #
 149 # Checks for FreeType
 150 #
 151
 152 AC_ARG_WITH(freetype-config, [  --with-freetype-config=PROG   Use FreeType configuration program PROG], freetype_config=$withval, freetype_config=yes)
 153
 154 if test "$freetype_config" = "yes"; then
 155         AC_PATH_PROG(ft_config,freetype-config,no)
 156         if test "$ft_config" = "no"; then
 157                 AC_MSG_ERROR([You must have freetype installed; see http://www.freetype.org/])
 158         fi
 159 else
 160         ft_config="$freetype_config"
 161 fi
 162
 163 FREETYPE_CFLAGS="`$ft_config --cflags`"
 164 FREETYPE_LIBS="`$ft_config --libs`"
 165
 166 AC_SUBST(FREETYPE_LIBS)
 167 AC_SUBST(FREETYPE_CFLAGS)
 168
 169 #
 170 # Check to see whether we have:
 171 #  FT_Get_Next_Char
 172 #  FT_Get_BDF_Property
 173 #  FT_Get_PS_Font_Info
 174 #  FT_Has_PS_Glyph_Names
 175 #
 176
 177 fontconfig_save_libs="$LIBS"
 178 fontconfig_save_cflags="$CFLAGS"
 179 LIBS="$LIBS $FREETYPE_LIBS"
 180 CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
 181 AC_CHECK_FUNCS(FT_Get_Next_Char FT_Get_BDF_Property FT_Get_PS_Font_Info FT_Has_PS_Glyph_Names FT_Get_X11_Font_Format)
 182 AC_CHECK_MEMBER(FT_Bitmap_Size.y_ppem,
 183                 HAVE_FT_BITMAP_SIZE_Y_PPEM=1,
 184                 HAVE_FT_BITMAP_SIZE_Y_PPEM=0,
 185 [#include <ft2build.h>
 186 #include FT_FREETYPE_H])
 187 AC_DEFINE_UNQUOTED(HAVE_FT_BITMAP_SIZE_Y_PPEM,$HAVE_FT_BITMAP_SIZE_Y_PPEM,
 188                    [FT_Bitmap_Size structure includes y_ppem field])
 189 CFLAGS="$fontconfig_save_cflags"
 190 LIBS="$fontconfig_save_libs"
 191
 192 #
 193 # Check expat configuration
 194 #
 195
 196 AC_ARG_WITH(expat,             [  --with-expat=DIR              Use Expat in DIR], expat=$withval, expat=yes)
 197 AC_ARG_WITH(expat-includes,    [  --with-expat-includes=DIR     Use Expat includes in DIR], expat_includes=$withval, expat_includes=yes)
 198 AC_ARG_WITH(expat-lib,         [  --with-expat-lib=DIR          Use Expat library in DIR], expat_lib=$withval, expat_lib=yes)
 199
 200 if test "$enable_libxml2" != "yes"; then
 201         case "$expat" in
 202         no)
 203         ;;
 204         *)
 205                 case "$expat_includes" in
 206                 yes)
 207                         case "$expat" in
 208                         yes)
 209                                 ;;
 210                         *)
 211                                 EXPAT_CFLAGS="-I$expat/include"
 212                                 ;;
 213                         esac
 214                         ;;
 215                 no)
 216                         EXPAT_CFLAGS=""
 217                         ;;
 218                 *)
 219                         EXPAT_CFLAGS="-I$expat_includes"
 220                         ;;
 221                 esac
 222                 case "$expat_lib" in
 223                 yes)
 224                         case "$expat" in
 225                         yes)
 226                                 EXPAT_LIBS="-lexpat"
 227                                 ;;
 228                         *)
 229                                 EXPAT_LIBS="-L$expat/lib -lexpat"
 230                                 ;;
 231                         esac
 232                         ;;
 233                 no)
 234                         ;;
 235                 *)
 236                         EXPAT_LIBS="-L$expat_lib -lexpat"
 237                         ;;
 238                 esac
 239
 240                 expatsaved_CPPFLAGS="$CPPFLAGS"
 241                 CPPFLAGS="$CPPFLAGS $EXPAT_CFLAGS"
 242                 expatsaved_LIBS="$LIBS"
 243                 LIBS="$LIBS $EXPAT_LIBS"
 244
 245                 AC_CHECK_HEADER(expat.h)
 246                 case "$ac_cv_header_expat_h" in
 247                 no)
 248                         AC_CHECK_HEADER(xmlparse.h)
 249                         case "$ac_cv_header_xmlparse_h" in
 250                         no)
 251                                 have_expat_header=no;
 252                                 ;;
 253                         yes)
 254                                 HAVE_XMLPARSE_H=1
 255                                 AC_SUBST(HAVE_XMLPARSE_H)
 256                                 AC_DEFINE_UNQUOTED(HAVE_XMLPARSE_H,$HAVE_XMLPARSE_H,
 257                                 [Use xmlparse.h instead of expat.h])
 258                                 have_expat_header=yes
 259                                 ;;
 260                         esac
 261                         ;;
 262                 yes)
 263                         have_expat_header=yes
 264                         ;;
 265                 esac
 266                 case "$have_expat_header" in
 267                 no)
 268                         expat=no
 269                         ;;
 270                 yes)
 271                         AC_CHECK_FUNCS(XML_SetDoctypeDeclHandler)
 272                         case "$ac_cv_func_XML_SetDoctypeDeclHandler" in
 273                         yes)
 274                                 HAVE_EXPAT=1
 275                                 AC_SUBST(HAVE_EXPAT)
 276                                 AC_DEFINE_UNQUOTED(HAVE_EXPAT,$HAVE_EXPAT,
 277                                 [Found a useable expat library])
 278                                 ;;
 279                         *)
 280                                 expat=no
 281                                 ;;
 282                         esac
 283                         ;;
 284                 esac
 285                 CPPFLAGS="$expatsaved_CPPFLAGS"
 286                 LIBS="$expatsaved_LIBS"
 287                 ;;
 288         esac
 289
 290         AC_SUBST(EXPAT_CFLAGS)
 291         AC_SUBST(EXPAT_LIBS)
 292
 293         case "$expat" in
 294         no)
 295                 EXPAT_CFLAGS=""
 296                 EXPAT_LIBS=""
 297
 298                 AC_MSG_WARN([Cannot find usable expat library. Trying to use libxml2 as fallback.])
 299                 ;;
 300         esac
 301 fi
 302
 303 #
 304 # Check libxml2 configuration
 305 #
 306
 307 AC_ARG_ENABLE(libxml2,         [  --enable-libxml2              Use libxml2 instead of Expat])
 308
 309 if test "$enable_libxml2" = "yes" -o "$expat" = "no"; then
 310     PKG_CHECK_MODULES([LIBXML2], [libxml-2.0 >= 2.6])
 311     AC_DEFINE_UNQUOTED(ENABLE_LIBXML2,1,[Use libxml2 instead of Expat])
 312
 313     AC_SUBST(LIBXML2_CFLAGS)
 314     AC_SUBST(LIBXML2_LIBS)
 315 fi
 316
 317 #
 318 # Set default font directory
 319 #
 320
 321 AC_ARG_WITH(default-fonts,     [  --with-default-fonts=DIR      Use fonts from DIR when config is busted], default_fonts="$withval", default_fonts=yes)
 322
 323 case "$default_fonts" in
 324 yes)
 325         if test "$os_win32" = "yes"; then
 326                 FC_DEFAULT_FONTS="WINDOWSFONTDIR"
 327                 AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "WINDOWSFONTDIR",
 328                                    [Windows font directory])
 329         else
 330                 FC_DEFAULT_FONTS="/usr/share/fonts"
 331                 AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "/usr/share/fonts",
 332                                    [System font directory])
 333         fi
 334         ;;
 335 *)
 336         FC_DEFAULT_FONTS="$default_fonts"
 337         AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "$default_fonts",
 338                            [System font directory])
 339         ;;
 340 esac
 341
 342 AC_SUBST(FC_DEFAULT_FONTS)
 343
 344 #
 345 # Add more fonts if available.  By default, add only the directories
 346 # with outline fonts; those with bitmaps can be added as desired in
 347 # local.conf or ~/.fonts.conf
 348 #
 349 AC_ARG_WITH(add-fonts,        [  --with-add-fonts=DIR1,DIR2,...Find additional fonts in DIR1,DIR2,... ], add_fonts="$withval", add_fonts=yes)
 350
 351 case "$add_fonts" in
 352 yes)
 353         FC_ADD_FONTS=""
 354         for dir in /usr/X11R6/lib/X11 /usr/X11/lib/X11 /usr/lib/X11; do
 355                 case x"$FC_ADD_FONTS" in
 356                 x)
 357                         sub="$dir/fonts"
 358                         if test -d "$sub"; then
 359                                 case x$FC_ADD_FONTS in
 360                                 x)
 361                                         FC_ADD_FONTS="$sub"
 362                                         ;;
 363                                 *)
 364                                         FC_ADD_FONTS="$FC_ADD_FONTS,$sub"
 365                                         ;;
 366                                 esac
 367                         fi
 368                         ;;
 369                 esac
 370         done
 371         AC_DEFINE_UNQUOTED(FC_ADD_FONTS,"$add_fonts",[Additional font directories])
 372         ;;
 373 no)
 374         FC_ADD_FONTS=""
 375         ;;
 376 *)
 377         FC_ADD_FONTS="$add_fonts"
 378         AC_DEFINE_UNQUOTED(FC_ADD_FONTS,"$add_fonts",[Additional font directories])
 379         ;;
 380 esac
 381
 382 AC_SUBST(FC_ADD_FONTS)
 383
 384 FC_FONTPATH=""
 385
 386 case "$FC_ADD_FONTS" in
 387 "")
 388         ;;
 389 *)
 390         FC_FONTPATH=`echo $FC_ADD_FONTS |
 391                         sed -e 's/^/<dir>/' -e 's/$/<\/dir>/' -e 's/,/<\/dir> <dir>/g'`
 392         ;;
 393 esac
 394
 395 AC_SUBST(FC_FONTPATH)
 396
 397 FC_FONTDATE=`LC_ALL=C date`
 398
 399 AC_SUBST(FC_FONTDATE)
 400
 401 AC_ARG_WITH(confdir,           [  --with-confdir=DIR            Use DIR to store configuration files (default /etc/fonts)], confdir="$withval", confdir=yes)
 402
 403 #
 404 # Set CONFDIR and FONTCONFIG_PATH
 405 #
 406
 407 case "$confdir" in
 408 no|yes)
 409         confdir='${sysconfdir}'/fonts
 410         ;;
 411 *)
 412         ;;
 413 esac
 414 AC_SUBST(confdir)
 415 CONFDIR=${confdir}
 416 AC_DEFINE_UNQUOTED(CONFDIR, "$CONFDIR",[Font configuration directory])
 417 AC_SUBST(CONFDIR)
 418
 419 #
 420 # Find out what language orthographies are included
 421 #
 422
 423 ORTH_FILES=`cd ${srcdir}/fc-lang && echo *.orth`
 424 AC_SUBST(ORTH_FILES)
 425
 426 #
 427 # Let people not build/install docs if they don't have docbook
 428 #
 429
 430 AC_CHECK_PROG(HASDOCBOOK, docbook2html, yes, no)
 431
 432 AM_CONDITIONAL(USEDOCBOOK, test "x$HASDOCBOOK" = xyes)
 433
 434 default_docs="yes"
 435 #
 436 # Check if docs exist or can be created
 437 #
 438 if test x$HASDOCBOOK = xno; then
 439         if test -f doc/fonts-conf.5; then
 440                 :
 441         else
 442                 default_docs="no"
 443         fi
 444 fi
 445
 446 AC_ARG_ENABLE(docs,           [  --disable-docs                Don't build and install documentation],,enable_docs=$default_docs)
 447
 448 AM_CONDITIONAL(ENABLE_DOCS, test "x$enable_docs" = xyes)
 449
 450 if test "x$enable_docs" = xyes; then
 451         DOCSRC="doc"
 452         tmp=funcs.$$
 453         cat $srcdir/doc/*.fncs | awk '
 454         /^@TITLE@/      { if (!done) { printf ("%s\n", $2); done = 1; } }
 455         /^@FUNC@/       { if (!done) { printf ("%s\n", $2); done = 1; } }
 456         /^@@/           { done = 0; }' > $tmp
 457         DOCMAN3=`cat $tmp | awk '{ printf ("%s.3 ", $1); }'`
 458         echo DOCMAN3 $DOCMAN3
 459         rm -f $tmp
 460 else
 461         DOCSRC=""
 462         DOCMAN3=""
 463 fi
 464
 465 AC_SUBST(DOCSRC)
 466 AC_SUBST(DOCMAN3)
 467
 468 #
 469 # Figure out where to install documentation
 470 #
 471
 472 AC_ARG_WITH(docdir,           [  --with-docdir=DIR             Use DIR to store documentation files (default ${datadir}/doc/fontconfig)], confdir="$withval")
 473
 474 if test "x$with_docdir" = "x" ; then
 475   DOCDIR='${datadir}/doc/fontconfig'
 476 else
 477   DOCDIR=$with_docdir
 478 fi
 479
 480 AC_SUBST(DOCDIR)
 481
 482 #
 483 # Make /var/cache/fontconfig directory available to source code
 484 #
 485
 486 pkgcachedir='${localstatedir}/cache/'${PACKAGE}
 487 AC_SUBST(pkgcachedir)
 488
 489 AC_OUTPUT([
 490 Makefile
 491 fontconfig/Makefile
 492 fc-lang/Makefile
 493 fc-glyphname/Makefile
 494 fc-case/Makefile
 495 src/Makefile
 496 src/fontconfig.def
 497 conf.d/Makefile
 498 fc-cache/Makefile
 499 fc-cat/Makefile
 500 fc-list/Makefile
 501 fc-match/Makefile
 502 doc/Makefile
 503 doc/version.sgml
 504 test/Makefile
 505 fontconfig.spec
 506 fontconfig.pc
 507 fonts.conf
 508 fontconfig-zip
 509 ])