configure.in

   1 dnl
   2 dnl  $Id$
   3 dnl
   4 dnl  Copyright © 2003 Keith Packard
   5 dnl
   6 dnl  Permission to use, copy, modify, distribute, and sell this software and its
   7 dnl  documentation for any purpose is hereby granted without fee, provided that
   8 dnl  the above copyright notice appear in all copies and that both that
   9 dnl  copyright notice and this permission notice appear in supporting
  10 dnl  documentation, and that the name of Keith Packard not be used in
  11 dnl  advertising or publicity pertaining to distribution of the software without
  12 dnl  specific, written prior permission.  Keith Packard makes no
  13 dnl  representations about the suitability of this software for any purpose.  It
  14 dnl  is provided "as is" without express or implied warranty.
  15 dnl
  16 dnl  KEITH PACKARD DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
  17 dnl  INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
  18 dnl  EVENT SHALL KEITH PACKARD BE LIABLE FOR ANY SPECIAL, INDIRECT OR
  19 dnl  CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
  20 dnl  DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
  21 dnl  TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
  22 dnl  PERFORMANCE OF THIS SOFTWARE.
  23 dnl
  24 dnl Process this file with autoconf to create configure.
  25
  26 AC_INIT(fonts.dtd)
  27
  28 dnl ==========================================================================
  29 dnl                               Versioning
  30 dnl ==========================================================================
  31
  32 dnl This is the package version number, not the shared library
  33 dnl version.  This same version number must appear in fontconfig/fontconfig.h
  34 dnl Yes, it is a pain to synchronize version numbers.  Unfortunately, it's
  35 dnl not possible to extract the version number here from fontconfig.h
  36 AM_INIT_AUTOMAKE(fontconfig, 2.2.90)
  37
  38 dnl libtool versioning
  39
  40 LT_CURRENT=1
  41 LT_REVISION=4
  42 AC_SUBST(LT_CURRENT)
  43 AC_SUBST(LT_REVISION)
  44 LT_AGE=0
  45
  46 LT_VERSION_INFO="$LT_CURRENT:$LT_REVISION:$LT_AGE"
  47 AC_SUBST(LT_VERSION_INFO)
  48
  49 LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
  50 AC_SUBST(LT_CURRENT_MINUS_AGE)
  51
  52 dnl ==========================================================================
  53
  54 AM_CONFIG_HEADER(config.h)
  55
  56 AC_PROG_CC
  57 AC_PROG_INSTALL
  58 AC_PROG_LN_S
  59 AC_LIBTOOL_WIN32_DLL
  60 AM_PROG_LIBTOOL
  61 AC_PROG_MAKE_SET
  62
  63 dnl ==========================================================================
  64
  65 case "$host" in
  66   *-*-mingw*)
  67     os_win32=yes
  68     ;;
  69   *)
  70     os_win32=no
  71 esac
  72 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "yes")
  73
  74 if test "$os_win32" = "yes"; then
  75   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
  76 fi
  77 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
  78
  79 dnl ==========================================================================
  80
  81 # Checks for header files.
  82 AC_HEADER_DIRENT
  83 AC_HEADER_STDC
  84 AC_CHECK_HEADERS([fcntl.h stdlib.h string.h unistd.h])
  85
  86 # Checks for typedefs, structures, and compiler characteristics.
  87 AC_C_CONST
  88 AC_TYPE_PID_T
  89
  90 # Checks for library functions.
  91 AC_FUNC_VPRINTF
  92 AC_CHECK_FUNCS([geteuid getuid link memmove memset mkstemp strchr strrchr strtol getopt getopt_long])
  93
  94 #
  95 # Checks for FreeType
  96 #
  97
  98 AC_ARG_WITH(freetype-config, [  --with-freetype-config=PROG   Use FreeType configuration program PROG], freetype_config=$withval, freetype_config=yes)
  99
 100 if test "$freetype_config" = "yes"; then
 101         AC_PATH_PROG(ft_config,freetype-config,no)
 102         if test "$ft_config" = "no"; then
 103                 AC_MSG_ERROR([You must have freetype installed; see http://www.freetype.org/])
 104         fi
 105 else
 106         ft_config="$freetype_config"
 107 fi
 108
 109 FREETYPE_CFLAGS="`$ft_config --cflags`"
 110 FREETYPE_LIBS="`$ft_config --libs`"
 111
 112 AC_SUBST(FREETYPE_LIBS)
 113 AC_SUBST(FREETYPE_CFLAGS)
 114
 115 #
 116 # Check to see whether we have FT_Get_First_Char(), new in 2.0.9
 117 #
 118
 119 fontconfig_save_libs=$LIBS
 120 LIBS="$LIBS $FREETYPE_LIBS"
 121 AC_CHECK_FUNCS(FT_Get_First_Char)
 122 LIBS=$fontconfig_save_libs
 123
 124 #
 125 # Check expat configuration
 126 #
 127
 128 AC_ARG_WITH(expat,             [  --with-expat=DIR              Use Expat in DIR], expat=$withval, expat=yes)
 129 AC_ARG_WITH(expat-includes,    [  --with-expat-includes=DIR     Use Expat includes in DIR], expat_includes=$withval, expat_includes=yes)
 130 AC_ARG_WITH(expat-lib,         [  --with-expat-lib=DIR          Use Expat library in DIR], expat_lib=$withval, expat_lib=yes)
 131
 132 case "$expat" in
 133 no)
 134         ;;
 135 *)
 136         case "$expat_includes" in
 137         yes|no)
 138                 EXPAT_CFLAGS=""
 139                 ;;
 140         *)
 141                 EXPAT_CFLAGS="-I$expat_includes"
 142                 ;;
 143         esac
 144         case "$expat_lib" in
 145         yes)
 146                 case "$expat" in
 147                 yes)
 148                         EXPAT_LIBS="-lexpat"
 149                         ;;
 150                 *)
 151                         EXPAT_LIBS="-L$expat/lib -lexpat"
 152                         ;;
 153                 esac
 154                 ;;
 155         no)
 156                 ;;
 157         *)
 158                 EXPAT_LIBS="-L$expat_lib -lexpat"
 159                 ;;
 160         esac
 161
 162         expatsaved_CPPFLAGS="$CPPFLAGS"
 163         CPPFLAGS="$CPPFLAGS $EXPAT_CFLAGS"
 164         expatsaved_LIBS="$LIBS"
 165         LIBS="$LIBS $EXPAT_LIBS"
 166
 167         AC_CHECK_HEADER(expat.h)
 168         case "$ac_cv_header_expat_h" in
 169         no)
 170                 AC_CHECK_HEADER(xmlparse.h)
 171                 case "$ac_cv_header_xmlparse_h" in
 172                 no)
 173                         have_expat_header=no;
 174                         ;;
 175                 yes)
 176                         HAVE_XMLPARSE_H=1
 177                         AC_SUBST(HAVE_XMLPARSE_H)
 178                         AC_DEFINE_UNQUOTED(HAVE_XMLPARSE_H,$HAVE_XMLPARSE_H,
 179                         [Use xmlparse.h instead of expat.h])
 180                         have_expat_header=yes
 181                         ;;
 182                 esac
 183                 ;;
 184         yes)
 185                 have_expat_header=yes
 186                 ;;
 187         esac
 188         case "$have_expat_header" in
 189         no)
 190                 expat=no
 191                 ;;
 192         yes)
 193                 AC_CHECK_FUNCS(XML_SetDoctypeDeclHandler)
 194                 case "$ac_cv_func_XML_SetDoctypeDeclHandler" in
 195                 yes)
 196                         HAVE_EXPAT=1
 197                         AC_SUBST(HAVE_EXPAT)
 198                         AC_DEFINE_UNQUOTED(HAVE_EXPAT,$HAVE_EXPAT,
 199                         [Found a useable expat library])
 200                         ;;
 201                 *)
 202                         expat=no
 203                         ;;
 204                 esac
 205                 ;;
 206         esac
 207         CPPFLAGS="$expatsaved_CPPFLAGS"
 208         LIBS="$expatsaved_LIBS"
 209         ;;
 210 esac
 211 AC_SUBST(EXPAT_LIBS)
 212 AC_SUBST(EXPAT_CFLAGS)
 213
 214 case "$expat" in
 215 no)
 216         AC_MSG_ERROR([Cannot find usable expat library. This could mean that your version is too old.])
 217         ;;
 218 esac
 219
 220 #
 221 # Set default font directory
 222 #
 223
 224 AC_ARG_WITH(default-fonts,     [  --with-default-fonts=DIR      Use fonts from DIR when config is busted], default_fonts="$withval", default_fonts=yes)
 225
 226 case "$default_fonts" in
 227 yes)
 228         if test "$os_win32" = "yes"; then
 229                 FC_DEFAULT_FONTS="WINDOWSFONTDIR"
 230                 AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "WINDOWSFONTDIR",
 231                                    [Windows font directory])
 232         else
 233                 FC_DEFAULT_FONTS="/usr/share/fonts"
 234                 AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "/usr/share/fonts",
 235                                    [System font directory])
 236         fi
 237         ;;
 238 *)
 239         FC_DEFAULT_FONTS="$default_fonts"
 240         AC_DEFINE_UNQUOTED(FC_DEFAULT_FONTS, "$default_fonts",
 241                            [System font directory])
 242         ;;
 243 esac
 244
 245 AC_SUBST(FC_DEFAULT_FONTS)
 246
 247 #
 248 # Add more fonts if available.  By default, add only the directories
 249 # with outline fonts; those with bitmaps can be added as desired in
 250 # local.conf or ~/.fonts.conf
 251 #
 252 AC_ARG_WITH(add-fonts,        [  --with-add-fonts=DIR1,DIR2,...Find additional fonts in DIR1,DIR2,... ], add_fonts="$withval", add_fonts=yes)
 253
 254 case "$add_fonts" in
 255 yes)
 256         FC_ADD_FONTS=""
 257         for dir in /usr/X11R6/lib/X11 /usr/X11/lib/X11 /usr/lib/X11; do
 258                 case x"$FC_ADD_FONTS" in
 259                 x)
 260                         if test -d "$dir/fonts"; then
 261                                 for sub in "$dir"/fonts/*; do
 262                                         if ls "$sub" | grep -q -i '\.pf\|\.tt\|\.ot'; then
 263                                                 case x$FC_ADD_FONTS in
 264                                                 x)
 265                                                         FC_ADD_FONTS="$sub"
 266                                                         ;;
 267                                                 *)
 268                                                         FC_ADD_FONTS="$FC_ADD_FONTS,$sub"
 269                                                         ;;
 270                                                 esac
 271                                         fi
 272                                 done
 273                         fi
 274                         ;;
 275                 esac
 276         done
 277         AC_DEFINE_UNQUOTED(FC_ADD_FONTS,"$add_fonts",[Additional font directories])
 278         ;;
 279 no)
 280         FC_ADD_FONTS=""
 281         ;;
 282 *)
 283         FC_ADD_FONTS="$add_fonts"
 284         AC_DEFINE_UNQUOTED(FC_ADD_FONTS,"$add_fonts",[Additional font directories])
 285         ;;
 286 esac
 287
 288 AC_SUBST(FC_ADD_FONTS)
 289
 290 FC_FONTPATH=""
 291
 292 case "$FC_ADD_FONTS" in
 293 "")
 294         ;;
 295 *)
 296         FC_FONTPATH=`echo $FC_ADD_FONTS |
 297                         sed -e 's/^/<dir>/' -e 's/$/<\/dir>/' -e 's/,/<\/dir> <dir>/g'`
 298         ;;
 299 esac
 300
 301 AC_SUBST(FC_FONTPATH)
 302
 303 FC_FONTDATE=`date`
 304
 305 AC_SUBST(FC_FONTDATE)
 306
 307 AC_ARG_WITH(confdir,           [  --with-confdir=DIR            Use DIR to store configuration files (default /etc/fonts)], confdir="$withval", confdir=yes)
 308
 309 #
 310 # Set CONFDIR and FONTCONFIG_PATH
 311 #
 312
 313 case "$confdir" in
 314 no|yes)
 315         confdir='${sysconfdir}'/fonts
 316         ;;
 317 *)
 318         ;;
 319 esac
 320 AC_SUBST(confdir)
 321 CONFDIR=${confdir}
 322 AC_DEFINE_UNQUOTED(CONFDIR, "$CONFDIR",[Font configuration directory])
 323 AC_SUBST(CONFDIR)
 324
 325 #
 326 # Find out what language orthographies are included
 327 #
 328
 329 ORTH_FILES=`cd fc-lang && echo *.orth`
 330 AC_SUBST(ORTH_FILES)
 331
 332 #
 333 # Let people not build/install docs if they don't have docbook
 334 #
 335
 336 AC_CHECK_PROG(HASDOCBOOK, docbook2html, yes, no)
 337
 338 AC_ARG_ENABLE(docs,           [  --disable-docs                Don't build and install documentation],,enable_docs=yes)
 339
 340 if test "x$enable_docs" = xyes; then
 341   if test "x$HASDOCBOOK" != xyes; then
 342     enable_docs=no
 343   fi
 344 fi
 345
 346 AM_CONDITIONAL(ENABLE_DOCS, test "x$enable_docs" = xyes)
 347
 348 #
 349 # Figure out where to install documentation
 350 #
 351
 352 AC_ARG_WITH(docdir,           [  --with-docdir=DIR             Use DIR to store documentation files (default ${datadir}/doc/fontconfig)], confdir="$withval")
 353
 354 if test "x$with_docdir" = "x" ; then
 355   DOCDIR='${datadir}/doc/fontconfig'
 356 else
 357   DOCDIR=$with_docdir
 358 fi
 359
 360 AC_SUBST(DOCDIR)
 361
 362 AC_OUTPUT([
 363 Makefile
 364 fontconfig/Makefile
 365 fc-lang/Makefile
 366 fc-glyphname/Makefile
 367 src/Makefile
 368 src/fontconfig.def
 369 fc-cache/Makefile
 370 fc-list/Makefile
 371 fc-match/Makefile
 372 doc/Makefile
 373 doc/version.sgml
 374 test/Makefile
 375 fontconfig.spec
 376 fontconfig.pc
 377 fonts.conf
 378 fontconfig-zip
 379 ])